Option Explicit
Sub TestSelectedMessage()
    Dim olMsg As MailItem
    On Error Resume Next
    Set olMsg = ActiveExplorer.Selection.Item(1)
    CheckMail olMsg
lbl_Exit:
    Exit Sub
End Sub

Sub CheckMail(olItem As Outlook.MailItem)
Dim sSubject As String
Dim sTextRow As String
Dim sSearch As String
Dim vSearch As Variant
Dim sPath As String
Dim sFileName As String: sFileName = "C:\Path\CheckList.txt" 'change as appropriate
Dim iFileNo As Integer: iFileNo = FreeFile
Dim i As Integer
Dim j As Long
    Open sFileName For Input As #iFileNo
    sSubject = LCase(olItem.subject)

    Do While Not EOF(iFileNo)
        Line Input #iFileNo, sTextRow
        i = 0
        sPath = Split(sTextRow, "|")(1)
        sSearch = Split(sTextRow, "|")(0)
        vSearch = Split(sSearch, "+")
        For j = LBound(vSearch) To UBound(vSearch)
            If InStr(1, sSubject, LCase(vSearch(j))) > 0 Then
                i = i + 1
            End If
        Next j
        If i = UBound(vSearch) + 1 Then
            MsgBox sPath
            GetFolder sPath
            Exit Do
        End If
    Loop
    Close #iFileNo
End Sub

Sub GetFolder(strFolder As String)
    Shell "C:\Windows\SysWOW64\explorer.exe /root," & strFolder, vbNormalFocus
lbl_Exit:
    Exit Sub
End Sub