Microsoft Office Forums

Go Back   Microsoft Office Forums > >

 
 
Thread Tools Display Modes
Prev Previous Post   Next Post Next
  #3  
Old 08-03-2018, 04:13 PM
macropod's Avatar
macropod macropod is offline Automatic - Appendix? Listing of Hyperlinks Windows 7 64bit Automatic - Appendix? Listing of Hyperlinks Office 2010 32bit
Administrator
 
Join Date: Dec 2010
Location: Canberra, Australia
Posts: 22,369
macropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond reputemacropod has a reputation beyond repute
Default

You could use a macro like:
Code:
Sub Demo()
Dim RngDoc As Range, RngOut As Range, Fld As Field
With ActiveDocument
  .Range.InsertAfter vbCr & Chr(12)
  Set RngDoc = .Range
  RngDoc.End = RngDoc.End - 2
  Set RngOut = .Characters.Last
  For Each Fld In RngDoc.Fields
    Select Case Fld.Type
      Case wdFieldData, wdFieldDatabase, wdFieldDDE, wdFieldDDEAuto, wdFieldImport, _
        wdFieldInclude, wdFieldIncludePicture, wdFieldIncludeText, wdFieldRefDoc
        With RngOut
          .InsertAfter vbCr
          .Characters.Last.Text = Fld.LinkFormat.SourceFullName
        End With
      Case wdFieldHyperlink
        With RngOut
          .InsertAfter vbCr
          .Characters.Last.FormattedText = Fld.Result.FormattedText
        End With
    End Select
  Next
  RngOut.Collapse wdCollapseStart
  RngOut.Text = "External Links"
End With
End Sub
Hyperlinks are retained as such; in all other cases, the list simply indicates the path & name of the source file.

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
For Mac macro installation & usage instructions, see: https://wordmvp.com/Mac/InstallMacro.html
__________________
Cheers,
Paul Edstein
[Fmr MS MVP - Word]
Reply With Quote
 



Similar Threads
Thread Thread Starter Forum Replies Last Post
Automatic - Appendix? Listing of Hyperlinks Appendix field switches LadyBug679 Word 10 11-05-2015 03:39 PM
Appendix, Tables and Index tanias Word 1 05-21-2014 11:08 AM
Automatic Appendix darksupernova Word 8 03-02-2013 04:12 AM
Appendix Page Numbering ffuhharas Word 1 02-09-2012 12:23 PM
No page number on appendix please davidaexp1 Word 0 08-22-2006 06:19 PM

Other Forums: Access Forums

All times are GMT -7. The time now is 07:30 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions Inc.
Search Engine Optimisation provided by DragonByte SEO (Lite) - vBulletin Mods & Addons Copyright © 2025 DragonByte Technologies Ltd.
MSOfficeForums.com is not affiliated with Microsoft