Wanted: Printable List of Built-in Word styles

macropod · #2 07-19-2012, 03:51 PM

Try the following macro in an empty document:

Code:

Sub GetBuiltinParaStyleDefs()
Dim oSty As Style, StrSty As String, TbStp As TabStop, SngTab As Single
With ActiveDocument
  For Each oSty In .Styles
    With oSty
      StrSty = ""
      If .BuiltIn = True Then
        If .Type = wdStyleTypeParagraph Then
          With .ParagraphFormat
            StrSty = "Style: " & ActiveDocument.Styles(oSty).NameLocal & vbTab
            StrSty = StrSty & StrSty & "Alignment: " & .Alignment
            StrSty = StrSty & Chr(11) & "Font: " & ActiveDocument.Styles(oSty).Font.Name
            If ActiveDocument.Styles(oSty).Font.Bold = True Then StrSty = StrSty & " (Bold)"
            StrSty = StrSty & vbTab & "Size: " & ActiveDocument.Styles(oSty).Font.Size
            StrSty = StrSty & Chr(11) & "First Line Indent: " & PointsToInches(.FirstLineIndent)
            StrSty = StrSty & Chr(11) & "Right Indent: " & PointsToInches(.RightIndent)
            StrSty = StrSty & Chr(11) & "Left Indent: " & PointsToInches(.LeftIndent)
            StrSty = StrSty & Chr(11) & "Space After: " & PointsToInches(.SpaceAfter)
            StrSty = StrSty & Chr(11) & "Space Before: " & PointsToInches(.SpaceBefore)
            For Each TbStp In .TabStops
              StrSty = StrSty & Chr(11) & "TabStop Alignment: "
              Select Case TbStp.Alignment
                Case 0: StrSty = StrSty & "Left"
                Case 1: StrSty = StrSty & "Center"
                Case 2: StrSty = StrSty & "Right"
                Case 3: StrSty = StrSty & "Decimal"
                Case 4: StrSty = StrSty & "Bar"
                Case 6: StrSty = StrSty & "List"
              End Select
              StrSty = StrSty & " @ " & PointsToInches(TbStp.Position)
            Next
            StrSty = StrSty & vbCr
          End With
        End If
      End If
    End With
    .Range.InsertAfter StrSty
  Next
End With
End Sub

This will output a list of all the paragraph Styles in your document, with their basic attributes.

For installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
New Page - When Not Wanted	pgrant	Word	2	06-07-2012 02:42 PM
Quick Styles Set saved but it doesnt appear at the styles list!	Pedro77	Word	3	10-15-2011 05:17 AM
Very frequent heading style, but still not built in Word!!!!! why???	Jamal NUMAN	Word	17	06-30-2011 05:47 PM
Multi-level list styles	qochi	Word	1	05-31-2011 01:16 AM
The list of styles appears in different way in different document?????	Jamal NUMAN	Word	4	04-28-2011 05:40 AM