Opening documents and initial layout

cyndor · #1 03-08-2012, 06:13 AM

Hello,

Using Word 2010. I have a database of 500 Word documents. I would like for these to be opened all in the same fashion. Sometimes I open a document, and the initial layout is set to be viewed at 80%, others at 120%, etc. Is there a setting where I could make sure that all these documents open the same way? Or does the document retain the layout as it was initially saved?

Thanks for any insights!

Luke

macropod · #2 03-08-2012, 09:58 PM

Hi Luke,

Add the following code to your 'Normal' template's 'ThisDocument' module:

Code:

Option Explicit
Private Sub Document_New()
Call Document_Open
End Sub
 
Private Sub Document_Open()
With ActiveWindow
  On Error Resume Next
  'Reduce flickering while changing settings
  .Visible = False
  'Switch to Print Preview mode
  If .View.SplitSpecial = wdPaneNone Then
    .ActivePane.View.Type = wdPrintView
  Else
    .View.Type = wdPrintView
  End If
  With .ActivePane.View.Zoom
    'Set for a 1-page view
    .PageColumns = 1
    'Initialize for best fit
    .PageFit = wdPageFitBestFit
    'Test zoom % and reduce to 125% max
    If .Percentage > 125 Then .Percentage = 125
  End With
  'Display the Rulers
  .ActivePane.DisplayRulers = True
  'Restore the window now that we're finished
  .Visible = True
End With
End Sub

With this code, every document will be opened in Print layout view and any document that can be opened at 125% will do so. Wider documents (eg in landscape format) will open at whatever zoom amount allows them to fit on screen. Word's rulers will also be displayed.

cyndor · #3 03-09-2012, 06:16 AM

Thanks!
Have a great day!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
All my word documents are opening as blank.	Omni1	Word	1	07-14-2011 04:23 PM
Initial Mistake	simpson55	Outlook	2	02-02-2011 09:52 AM
Not all documents opening	wchalverson	Office	0	08-24-2010 04:55 PM
Regarding initial configuration in MS Office	minerva	Office	1	10-25-2009 02:30 AM
User Name Prompt Appears When Opening Documents	galleherjazz	Office	0	07-30-2009 08:15 PM