Auto Create/Format a Word Document based on Check Boxes

macropod · #21 05-07-2020, 02:30 PM

Try the following. In this case, if a 'Not Applicable' result is required, the macro deletes the original empty second column and widens the original third column to compensate.

Code:

Sub DeleteCheckedContent()
Application.ScreenUpdating = False
Dim Tbl As Table, r As Long
For Each Tbl In ActiveDocument.Tables
  With Tbl
    If .Cell(1, 1).Range.ContentControls.Count = 1 Then
      If .Cell(1, 1).Range.ContentControls(1).Checked = True Then
        For r = .Rows.Count To 2 Step -1
          .Rows(r).Delete
        Next
        .Rows.Add
        If .Columns.Count > 2 Then
          .Columns(3).Width = .Columns(2).Width + .Columns(3).Width
          .Columns(2).Delete
        End If
        .Cell(2, 2).Range.Text = "Not applicable"
      Else
        For r = .Rows.Count To 2 Step -1
          If .Cell(r, 1).Range.ContentControls(1).Checked = True Then .Rows(r).Delete
        Next
      End If
      .Columns(1).Delete
    End If
  End With
Next
Application.ScreenUpdating = True
End Sub

If you want to leave the columns intact, delete or comment-out:

Code:

        If .Columns.Count > 2 Then
          .Columns(3).Width = .Columns(2).Width + .Columns(3).Width
          .Columns(2).Delete
        End If

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Auto-populate Text Field When I Click Check Boxes	LobaBlanca	Word VBA	2	03-14-2019 08:10 PM
Print documents based on boxes checked in word document	eshiffman	Word VBA	8	04-05-2018 06:26 AM
Need to create document that will auto insert text based on parameters	parisfranco	Word	13	07-25-2017 03:21 PM
Word document with check boxes	JohnW	Word	3	12-01-2016 07:43 AM
Table - Check Boxes - Create Select All	lajohn1963	Word Tables	2	09-25-2010 11:18 AM