Rookie help with actually writing a macro

barrskog · #1 11-03-2019, 10:30 PM

Hi!

I'm a Word and programming rookie, but eager to learn more. I'm looking to create a simple find and replace macro, and I've been searching the forums (and googling for other tips) and there's of course plenty of solutions out there. However, I can get the macro to work even when copying the text and replace the Words in the macro that I want to replace. So obviously I'm missing out on something.

The Words I want to replace is:
qq,ohb,krp,ljd,§
With:
<olp>,<spn>,<vocalized_noise>,<noise>,(nothing, ie removed)

The macro I've find which I Think should do this is the one below. However, I'm getting red lines and syntax errors when posting it in the editor. I would be very happy if someone could Point out whats the problem and help me get a macro that can be copy pasted. Yes - I'm that rookie.

Sub MultiReplace()
Dim StrOld As String, StrNew As String
Dim RngFind As Range, RngTxt As Range, i As Long
StrOld = "qq,ohb,krp,ljd,§"
StrNew = "<olp>,<spn>,<vocalized_noise>,<noise>,&qu ot;
Set RngTxt = Selection.Range

For i = 0 To UBound(Split(StrOld, ",&quot

)
Set RngFind = RngTxt.Duplicate
With RngFind.Find
.ClearFormatting
.Replacement.ClearFormatting
.Text = Split(StrOld, ",&quot

(i)
.Replacement.Text = Split(StrNew, ",&quot

(i)
.Format = False
.MatchWholeWord = True
.MatchAllWordForms = False
.MatchWildcards = False
.Execute Replace:=wdReplaceAll
End With
Next
End Sub

gmayor · #2 11-04-2019, 05:05 AM

Code:

Sub MultiReplace()
Dim StrOld() As Variant, StrNew() As Variant
Dim RngFind As Range, RngTxt As Range, i As Long
    StrOld = Array("qq", "ohb", "krp", "ljd", "§")
    StrNew = Array("<olp>", "<spn>", "<vocalized_noise>", "<noise>", "")
    Set RngTxt = Selection.Range
    For i = 0 To UBound(StrOld)
        Set RngFind = RngTxt.Duplicate
        With RngFind.Find
            .ClearFormatting
            .Replacement.ClearFormatting
            .Text = StrOld(i)
            .Replacement.Text = StrNew(i)
            .Format = False
            .MatchWholeWord = True
            .MatchAllWordForms = False
            .MatchWildcards = False
            .Execute Replace:=wdReplaceAll
        End With
    Next
    Set RngFind = Nothing: Set RngTxt = Nothing
End Sub

barrskog · #3 11-04-2019, 09:55 PM

Big thanks - worked like a charm!

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Writing a Macro which will search for the content of a cell rather than it's value	Sears36	Excel Programming	1	05-11-2017 07:55 AM
Need help writing a macro to bring images to the front	readheads	Word	0	11-23-2013 07:37 AM
Writing a Macro in VBA	johnny51981	Project	1	06-22-2011 02:17 AM
automatic start of macro + help on writing helper function	vsempoux	Word	3	10-09-2009 03:01 AM
Macro Writing	cweachter	Excel	0	08-09-2008 08:30 PM