word 2003 to word 2010 conversion.

[Ramke]

Hi All,

We have around 10000 word 2003 documents (saved as xml) into sql server database as binary object field. We used interopt facility to mailmerge the data into the document using c# code. Now after upgrading the OS from XP to WIN7 64bit and upgradeing office 2003 to office 2010 (32bit), the interopt does not work as expected on the aspx pages. MS recommended to use openxml sdk with the c# code. But I need to convert all my word 2003 document into word 2010 docx as quickly as possible as openxml sdk does not recognize the word 2003 xml documents. It can recognize only word 2010 docx files not any xml docs.

We need some direction on this issue. can someone help?
regards
ramki

[macropod]

You can convert a whole folder of documents with a simple macro:

Sub ConvertFiles()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""
  If InStrRev(strFile, ".docx") = 0 Then
    Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, _
      AddToRecentFiles:=False, Visible:=False)
    wdDoc.SaveAs2 FileName:=strFolder & "\" & Left(strFile, InStrRev(strFile, ".doc")) & "docx", _
      Fileformat:=wdFormatXMLDocument, AddToRecentFiles:=False
    wdDoc.Close SaveChanges:=False
  End If
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function