Need Help with Below Code

macropod · #4 03-30-2014, 09:05 AM

Well, apart from the fact you deleted an existing expression in that macro, you added a space to the start of the new Find expression, omitted a new Replace expression, which means the preceding character would be deleted and a paragraph inserted in its place and, by putting it after the code that applies the 'Strong' Style, would turn the replaced output bold. Try:

Code:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Text = "([!1-9])[0]{1,}([0-9]{1,})"
    .Replacement.Text = "\1\2"
    .Execute Replace:=wdReplaceAll
  End With
End With
Application.ScreenUpdating = True
End Sub

or, to integrate it into yesterday's macro:

Code:

Sub Demo()
Application.ScreenUpdating = False
With ActiveDocument.Range
  .InsertBefore " "
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Forward = True
    .Wrap = wdFindContinue
    .Format = False
    .MatchWildcards = True
    .Text = "([!1-9])[0]{1,}([0-9]{1,})"
    .Replacement.Text = "\1\2"
    .Execute Replace:=wdReplaceAll
    .Text = ".([0-9]{1,3}.)"
    .Replacement.Text = ". \1"
    .Execute Replace:=wdReplaceAll
    .Text = " ([a-e].)"
    .Replacement.Text = "^p\1"
    .Execute Replace:=wdReplaceAll
    .Replacement.Style = "Strong"
    .Text = " ([0-9]{1,3}.)"
    .Execute Replace:=wdReplaceAll
  End With
  .Characters.First.Delete
End With
Application.ScreenUpdating = True
End Sub

PS: When posting code, please use the code tags. They're on the 'Go Advanced' tab.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Userform Code not quite right - help please	vbanovice	Word VBA	1	09-29-2013 09:20 PM
outlook vba code help	HxG	Outlook	0	09-20-2012 10:42 PM
Where does my code go?	rbaldwin	Word VBA	3	03-14-2012 02:31 PM
Help with VBA Code Modification	OTPM	Excel Programming	0	09-16-2011 07:10 AM
vbc code	rajpeter	Excel Programming	2	09-13-2011 02:29 PM