How to delete a powerpoint slide based on keywords in the "Notes" field?

rupd911 · #1 02-17-2021, 06:35 PM

Hello everyone,

Can someone help me with this:

Problem Statement: I have a powerpoint file with several hundred slides and each slide has some notes in the Notes field. I also have another text file which has a number of keywords. The idea is to develop an automation script that can read the text file and delete all the slides in the powerpoint where one of the words in the notes field matches the keyword.

Thanks,
RUPD

JohnWilson · #2 02-18-2021, 07:10 AM

This should at least give you a start. Make sure you keep a copy of the original!! Obviously change the path to the text file.

Code:

Sub Read_Txt_and_Check()

Dim fileNum As Integer
Dim RayTxt() As String
Dim L As Long
Dim T As Long
Dim b_Found As Boolean

fileNum = FreeFile
Open "C:\Users\info\Desktop\text.txt" For Input As fileNum
ReDim RayTxt(0)
Do While Not EOF(fileNum)
    ReDim Preserve RayTxt(UBound(RayTxt) + 1)
    Line Input #fileNum, RayTxt(UBound(RayTxt))
Loop
Close #fileNum

For L = ActivePresentation.Slides.Count To 1 Step -1
b_Found = False
For T = LBound(RayTxt) To UBound(RayTxt)
If word_Found(RayTxt(T), ActivePresentation.Slides(L).NotesPage.Shapes(2).TextFrame.TextRange) Then
b_Found = True
Exit For
End If
Next T
If b_Found Then ActivePresentation.Slides(L).Delete
Next L
End Sub

Function word_Found(strword As String, otxtR As TextRange) As Boolean
On Error Resume Next
Dim found As TextRange
Set found = otxtR.Find(FindWhat:=strword, MatchCase:=False, Wholewords:=True)
If Not found Is Nothing Then word_Found = True
End Function

macropod · #3 02-18-2021, 01:02 PM

Cross-posted (and answered before posting here) at: Extract first line of notes section on each slide - how to?
For cross-posting etiquette, please read: Excelguru Help Site - A message to forum cross posters

JohnWilson · #4 02-18-2021, 01:43 PM

Not quite the same question though.

macropod · #5 02-18-2021, 01:49 PM

Initially, no. However, by the end of the thread at VBAX it's clear that the OP is seeking a solution to the same problem on both forums.

rupd911 · #6 02-18-2021, 08:52 PM

Quote:

Originally Posted by JohnWilson

This should at least give you a start. Make sure you keep a copy of the original!! Obviously change the path to the text file.

Code:

Sub Read_Txt_and_Check()

Dim fileNum As Integer
Dim RayTxt() As String
Dim L As Long
Dim T As Long
Dim b_Found As Boolean

fileNum = FreeFile
Open "C:\Users\info\Desktop\text.txt" For Input As fileNum
ReDim RayTxt(0)
Do While Not EOF(fileNum)
    ReDim Preserve RayTxt(UBound(RayTxt) + 1)
    Line Input #fileNum, RayTxt(UBound(RayTxt))
Loop
Close #fileNum

For L = ActivePresentation.Slides.Count To 1 Step -1
b_Found = False
For T = LBound(RayTxt) To UBound(RayTxt)
If word_Found(RayTxt(T), ActivePresentation.Slides(L).NotesPage.Shapes(2).TextFrame.TextRange) Then
b_Found = True
Exit For
End If
Next T
If b_Found Then ActivePresentation.Slides(L).Delete
Next L
End Sub

Function word_Found(strword As String, otxtR As TextRange) As Boolean
On Error Resume Next
Dim found As TextRange
Set found = otxtR.Find(FindWhat:=strword, MatchCase:=False, Wholewords:=True)
If Not found Is Nothing Then word_Found = True
End Function

Thanks a ton! this worked like magic !!

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
How to view the names of "linked" contacts under the notes field	ChairPotato	Outlook	0	04-24-2020 12:55 PM
Error: "Changes made were lost...reconnect with server", when switching "from" field	randhurrle	Outlook	2	02-25-2015 06:51 PM
How do I delete the names under "Exceptions" when I use the "Restrict Editing" feature in Word?	MengS	Word	0	02-25-2015 02:57 PM
disappearing content of the "Notes" field in different views	heiterbiswolkig	Project	3	05-19-2014 07:28 AM
"Table of content" based on "Normal Style" behavior!!!!	Jamal NUMAN	Word	4	07-08-2011 04:12 AM