Sequential numbering across multiple docs

mslearner · #1 06-23-2011, 03:11 PM

I'm creating a maintenance work-order system for a commercial property management company and need each work order to be sequentially numbered automatically upon opening. I've tried creating a field which ties to an original source document using the following:

{INCLUDETEXT "Drive:\\Filepath\\Filename.Extension"}
This simply inserts the entire original document into the field.

{INCLUDETEXT "Drive:\\Filepath\\Filename.Extension" \!}
This does the same as the above

and

{INCLUDETEXT "Drive:\\Filepath\\Filename.Extension" "bookmark name"}
This just shows a blank field with no data.

The field code that I have in the original document is: seq workorder \# 00# \r000501 \* MERGEFORMAT

What am I doing wrong here?

macropod · #2 06-23-2011, 10:35 PM

Hi mslearner,

That approach won't give you an automatically-incrementing work order number.

The following macro (which I wrote for invoice generation) inserts and increments a number from a text (ini) file. It should serve your needs equally well.

Code:

Private Sub Document_New()
Application.ScreenUpdating = False
Dim InvoiceFile As String, InvNum As String
'Save ini file in the Word startup folder.
InvoiceFile = Options.DefaultFilePath(wdStartupPath) & "\Invoice.ini"
'or, by using the following line, the Workgroup folder
'InvoiceFile = Options.DefaultFilePath(wdWorkgroupTemplatesPath) & "\Invoice.ini"
InvNum = System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum")
'If there is no InvoiceNumber reference in the ini file
'Create one and set the number to 1, otherwise increment the number
If InvNum = "" Then
  InvNum = 1
Else
  InvNum = InvNum + 1
End If
System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum") = InvNum
With ActiveDocument
  'Update the value stored in the document property
  .CustomDocumentProperties("InvNum") = InvNum
  'Update the fields in the document
  .Fields.Update
End With
Application.ScreenUpdating = True
End Sub

To use the code, you need to open your work order template and add the macro to its 'ThisDocument' code module.

Then, go to File|Info|Properties|Custom and add a document property named 'InvNum'.

Next, in the body of the work order template, position the insertion point where you want the work order number to appear and press Ctrl-F9 to create a pair of field braces (ie '{}') and type 'DOCPROPERTY InvNum' between the field braces, thus '{DOCPROPERTY InvNum}'. If you want to force the work order # to display leading 0s (eg 01234), add '\# 0000' to the field code, thus: '{DOCPROPERTY InvNum \# 0000}'.

Finally, save the template as a Word document Template (ie with a '.dot' (Word 2004 & earlier) or '.dotm' (Word 2007 & later) extension, via File|Save As), named 'Invoice' (or another suitable name).

Now, whenever you want to create a new work order, simply go to File|New and select 'work order' (or your preferred name). You'll get an work order with the next available number. The last-used number is held in a file named 'Invoice.ini' in your Word Startup folder. In case you need it, there's a commented-out line to store the 'Invoice.ini' in your Word Workgroup folder instead, so that others in your workgroup can access it also.

If you need to set the initial work order #, or reset it, you can do so manually, or use the following macro:

Code:

Sub ResetOrderNumber()
Dim InvoiceFile As String, InvNum As String
InvoiceFile = Options.DefaultFilePath(wdStartupPath) & "\Invoice.ini"
'or, if using a Workgroup folder
'InvoiceFile = Options.DefaultFilePath(wdWorkgroupTemplatesPath) & "\Invoice.ini"
InvNum = System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum")
InvNum = Trim(InputBox("What is the last valid Work Order Number?" & vbCrLf & _
  "The current number is: " & InvNum))
If IsNumeric(InvNum) Then
  System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum") = CInt(InvNum)
  End
Else
  If InvNum = "" Then End
End If
MsgBox "Renumbering error, please try again."
End Sub

mslearner · #3 06-24-2011, 01:41 PM

Thanks so much, this worked!

Regency · #4 08-03-2012, 08:54 AM

Paul,
Im having trouble with setting up the system in Word 2007. I found and recorded the macro you posted but was unable to find where i could store the 'InvNum' system to make the numbering work.
Thanks,
April

macropod · #5 08-03-2012, 08:33 PM

Hi April,

You need to create a custom document property named 'InvNum'. IIRC, you get there in Word 2007 via:
Alt-f > Prepare > Properties > Document Properties > Advanced Properties > Custom.

raichea · #6 11-16-2012, 08:46 AM

User error... all working now. Excuse the interruption... normal service will now be resumed.

jgreen90 · #7 12-09-2014, 09:02 AM

What macros should I be adding this to?

macropod · #8 12-09-2014, 01:13 PM

As clearly stated in post #2, you add it to the document template.

wolfgrrl · #9 06-07-2019, 04:15 AM

I realize that this is an old thread but I've been searching hours for a way to do this on a template. I've tried your macro and it's not functioning for me.

I get a compile error on the first line: ambiguous name detected: Document_New. I'm using Word 2010 and am opening my template from within Word.

Can you please help? Thank you!

macropod · #10 06-07-2019, 04:47 AM

The "ambiguous name detected: Document_New" message tells me that you already have a Document_New macro in the template. You can only have one such macro.

Charles Kenyon · #11 06-07-2019, 05:15 AM

If you give this macro a unique name, you can call it from the existing Document_New macro.

macropod · #12 06-07-2019, 05:20 AM

I'd be wanting to know what the existing one does before recommending that approach. Even assuming a call is appropriate, it may be so in one part of the existing macro but not in another.

wolfgrrl · #13 06-10-2019, 06:17 AM

Quote:

Originally Posted by macropod

I'd be wanting to know what the existing one does before recommending that approach. Even assuming a call is appropriate, it may be so in one part of the existing macro but not in another.

Is it possible to store the ini file on a network location? How would one format the macro to work with that?

The network location is a mapped drive on all machines.

wolfgrrl · #14 06-10-2019, 11:31 AM

This is the code I'm using.

Code:

Private Sub Document_New()
Application.ScreenUpdating = False
Dim InvoiceFile As String, InvNum As String
InvoiceFile = Options.DefaultFilePath(wdDocumentsPath) = "N:\Engineering\ECN & ER Forms" & "\NUMBERS.ini"
InvNum = System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum")
'If there is no InvoiceNumber reference in the ini file
'Create one and set the number to 1, otherwise increment the number
If InvNum = "" Then
  InvNum = 1
Else
  InvNum = InvNum + 1
End If
System.PrivateProfileString(InvoiceFile, "InvoiceNumber", "InvNum") = InvNum
With ActiveDocument
  'Update the value stored in the document property
  .CustomDocumentProperties("InvNum") = InvNum
  'Update the fields in the document
  .Fields.Update
End With
Application.ScreenUpdating = True
End Sub

InvNum exists in custom properties.

NUMBERS.ini is stored in the same location as the form on the network.

Getting the error shown below. Can someone assist?

macropod · #15 06-10-2019, 07:18 PM

For your situation, it would probably be best to create a Custom Document Property named 'InvNum' in the template, then use code like:

Code:

Private Sub Document_New()
Application.ScreenUpdating = False
Dim InvNum As String
With ThisDocument
  InvNum = .CustomDocumentProperties("InvNum") + 1
  .CustomDocumentProperties("InvNum") = InvNum
  '.Save
End With
With ActiveDocument
  'Update the value stored in the document property
  .CustomDocumentProperties("InvNum") = InvNum
  'Update the fields in the document
  .Fields.Update
End With
Application.ScreenUpdating = True
End Sub

Do note that the number will increment every time a new document is created from the template. If someone does that, then doesn't save the new document, you'll invariably end up with gaps in the numbers in the saved documents. You can, of course, manually edit the 'InvNum' Custom Document Property in the template, but it's better to avoid the situation in the first place. More complex code could be used to ensure the numbers are only updated when the template is closed, but you then run the risk of the same number being allocated twice if two or more documents are being created at the same time.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
How do I do a Sequential Numbering?	gburya	Word VBA	26	07-04-2017 03:29 PM
Sequential Page Numbering of Multiple Word Docs	bobmard	Word	8	08-24-2011 08:51 AM
Editing multiple docs	frankdh	Word	2	11-02-2010 10:59 AM
Please help with Numbering a document with multiple letters.	DJReality213	Office	1	01-15-2010 05:56 PM
Amend footer in multiple word docs?	compact	Word	2	02-24-2009 09:40 AM