automatic text formatting(justify)

macropod · #1 04-13-2011, 03:09 PM

Hi Metamag,

Often, when you paste text into Word from web sites, email or PDFs, you'll get a paragraph break at the end of each line within a logical paragraph, and two such breaks between logical paragraphs. Such text stubbornly refuses to honour justification, because there's nothing to justify - it's all a series on one-line paragraphs. You should be able to see this if you have Word configured to display formatting marks on-screen. Clicking the ¶ symbol on the toolbar/home tab toggles this on/off.

You can fix this kind of paragraph formatting using a series of wildcard Find/Replace actions, with:
Find = [ ^s^t]{1,}^13
Replace = ^p
Find = ([!^13])([^13])([!^13])
Replace = \1 \3
Find = [ ]{2,}
Replace = ^32
Find = ([a-z])-[ ]{1,}([a-z])
Replace = \1\2
Find = [^13]{1,}
Replace = ^p
Note that the above assumes there are at least two such paragraph breaks between the 'real' paragraphs.

A macro equivalent is:

Code:

Sub CleanUpPastedText()
'Turn Off Screen Updating
Application.ScreenUpdating = False
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Forward = True
  .Wrap = wdFindStop
  .Format = False
  .MatchAllWordForms = False
  .MatchSoundsLike = False
  .MatchWildcards = True
  'Eliminate spaces & tabs before paragraph breaks.
  .Text = "[ ^s^t]{1,}^13"
  .Replacement.Text = "^p"
  .Execute Replace:=wdReplaceAll
  'Replace single paragraph breaks with a space
  .Text = "([!^13])([^13])([!^13])"
  .Replacement.Text = "\1 \3"
  'Replace all double spaces with single spaces
  .Execute Replace:=wdReplaceAll
  .Text = "[ ]{2,}"
  .Replacement.Text = " "
  'Delete hypens in hyphenated text formerly split across lines
  .Execute Replace:=wdReplaceAll
  .Text = "([a-z])-[ ]{1,}([a-z])"
  .Replacement.Text = "\1\2"
  .Execute Replace:=wdReplaceAll
  'Limit paragraph breaks to one per 'real' paragraph.
  .Text = "[^13]{1,}"
  .Replacement.Text = "^p"
  .Execute Replace:=wdReplaceAll
End With
'Restore Screen Updating
Application.ScreenUpdating = True
End Sub

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
For Mac macro installation & usage instructions, see: http://word.mvps.org/Mac/InstallMacro.html

If you'd prefer to run the macro against just a selected range, change:
ActiveDocument
to:
Selection

Metamag · #2 04-13-2011, 04:08 PM

Quote:

Originally Posted by macropod

You can fix this kind of paragraph formatting using a series of wildcard Find/Replace actions, with:
Find = ([!^13])([^13])([!^13])
Replace = \1 \3

I used just that part and it fixed everything perfectly! Thank you so much!

Can you tell me what's the rest of the stuff for if just those two lines worked?

I did create that macro you posted but when I ran it I got this-

Probably it would have gotten the job done anyway.

macropod · #3 04-13-2011, 04:22 PM

Hi Metamag,

Quote:

Originally Posted by Metamag

Can you tell me what's the rest of the stuff for if just those two lines worked?

See the comments in the macro itself.

Quote:

I did create that macro you posted but when I ran it I got this-

That suggests your regional settings for Windows require that you change '{1,}' and '{2,}' in the code to '{1;}' and '{2;}'.

GJohansson · #4 08-11-2011, 08:22 AM

Quote:

Originally Posted by macropod

Hi Metamag,

Often, when you paste text into Word from web sites, email or PDFs, you'll get a paragraph break at the end of each line within a logical paragraph, and two such breaks between logical paragraphs. Such text stubbornly refuses to honour justification, because there's nothing to justify - it's all a series on one-line paragraphs. You should be able to see this if you have Word configured to display formatting marks on-screen. Clicking the ¶ symbol on the toolbar/home tab toggles this on/off.

You can fix this kind of paragraph formatting using a series of wildcard Find/Replace actions, with:
...

A macro equivalent is:
...

i like to justify text to make a long word document looks good. The problem is that this macro when i run it,
changes the all format of the document. Because delete all break lines between text, even the headers of the text. I would like this makro to run, and delete lines, on the text of a document between two styles that im giving to that macro not all the document. Because in that way, combine together even the heading of the document. Is that such way to do that? Im sending you an word document, that you understand what i want to do. I would like to do the same thing the macro does but only between the styles i said to do, to whole document such as between text of heading 1 and heading 2 or heading 2 and heading 3 because if i choose to do this to a whole document gives me problems such as formating of the style of heading 1 to whole document. You can run this macro to the document to see what exact giving.

Thread Tools
Show Printable Version Email this Page
Display Modes
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Automatic Formatting for whole row	Bacchanal Promotions	Excel	2	03-19-2011 05:12 AM
Office 2007 Mail Merge Issue - automatic formatting and revisions balloons	sharpie21	Office	1	10-10-2010 03:56 AM
Automatic insertion of blank pages or alternate text	Diopippo	Word	0	07-06-2010 12:13 AM
problem with automatic formatting on quotation marks	Bobosmite	Word	3	05-27-2010 07:06 PM
Templates: automatic text generation from Rich Text content control	Chickenmunga	Word	0	10-01-2008 11:16 AM