add some text before hyperlink fields

[geotso]

Hello,


I have some URLs, each one at the start of a new paragraph like "http://something" or "https://something" (without quotes) and I want to add before them a label "URL: ", like "URL: http://something" or "URL: https://something" (without quotes).


I've tried find and replace for: find ^phttp, replace with ^pURL: http, however it doesn't work, because the URLs are hyperlink fields and Word can't match the string.


Then, I tried to use: Alt+F9 to get the field codes and then find "^p{HYPERLINK http", that doesn't work either, because the "{" of the filed is not the same with the one of the keyboard...


Any thoughts?
Thanks

[gmayor]

Easy enough with a simple macro e.g

Sub Macro1()
Dim oLink As Hyperlink
Dim oRng As Range
    For Each oLink In ActiveDocument.Hyperlinks
        If oLink.Address Like "http*" Or oLink.Address Like "HTTP*" Then
            Set oRng = oLink.Range
            oRng.InsertBefore "URL: "
        End If
    Next oLink
End Sub

See Installing Macros

[geotso]

well, it's almost there...
I have to specify that I want the label only to the links at the start of a new line (paragraph or custom brake), and not the others, scattered all around the document.


Thanks

[gmayor]

Oops. I missed that bit
Try this one

Sub Macro1()
Dim oLink As Hyperlink
Dim oRng As Range
    For Each oLink In ActiveDocument.Hyperlinks
        If oLink.Address Like "http*" Or oLink.Address Like "HTTP*" Then
            Set oRng = oLink.Range
            If oRng.Start = oRng.Paragraphs(1).Range.Start Then
                oRng.InsertBefore "URL: "
            End If
        End If
    Next oLink
End Sub

[geotso]

Yes, that's it!


Thank you very much.