Changing english numerals to arabic numerals

[aligahk06]

Dear all,



I have two sided page layout, the left side is for english and the right side is for arabic.

i want to display right side i.e Arabic words and the numerals also in arabic .
The left side english and english / Roman numerals.

I went through some advanced options but it changed entire english numeral to arabic in single page.


rgds,

aligahk06

[LQuinn]

ok i think this will do it - 'different odd & even pages' for your footers

odd page footer page numbering
page \* roman

even page footer page numbering
page \* arabic

also, take a look at this How to control the page numbering in a Word document

[aligahk06]

Originally Posted by LQuinn

ok i think this will do it - 'different odd & even pages' for your footers

odd page footer page numbering
page \* roman

even page footer page numbering
page \* arabic

also, take a look at this How to control the page numbering in a Word document

Attached sample for a single page two sided.
Please help .

[macropod]

The following two macros convert numbers in the selected range between Western and Arabic/Persian. The code also provides for numbers written left-to-right and for right-to-left - the supplied function does the reversing. Comments in the code show how to change the text direction and which source/target scripts to use.

For PC macro installation & usage instructions, see: Installing Macros
For Mac macro installation & usage instructions, see: Word:mac - Install a Macro

Sub WesternNumberToArabic_or_Persian()
Dim Rng As Range, StrTmp As String, i As Long
Set Rng = Selection.Range
With Selection.Range
  With .Find
    .ClearFormatting
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = True
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Text = "[,.0-9]{1,}"
    .Replacement.Text = ""
  End With
  Do While .Find.Execute
    If .InRange(Rng) = False Then Exit Sub
    If .Characters.Last Like "[.,]" Then .End = .End - 1
    ' If the numbers are input right-to-left, use:
    StrTmp = Reverse(.Text)
    ' If the numbers are input left-to-right, use:
    StrTmp = .Text
    For i = 0 To 9
      ' For arabic #s, use
      StrTmp = Replace(StrTmp, Chr(48 + i), ChrW(17632 + i))
      ' For persian #s, use
      StrTmp = Replace(StrTmp, Chr(48 + i), ChrW(1776 + i))
    Next i
    .Text = StrTmp
    .Collapse (wdCollapseEnd)
  Loop
End With
End Sub

Sub Arabic_or_PersianNumberToWestern()
Dim Rng As Range, StrTmp As String, i As Long
Set Rng = Selection.Range
With Selection.Range
  With .Find
    .ClearFormatting
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = True
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    'For arabic #s, use:
    .Text = "[,." & ChrW(1632) & "-" & ChrW(1641) & "]{1,}"
    'For persian #s, use
    .Text = "[,." & ChrW(1776) & "-" & ChrW(1785) & "]{1,}"
    .Replacement.Text = ""
  End With
  Do While .Find.Execute
    If .InRange(Rng) = False Then Exit Sub
    If .Characters.Last Like "[.,]" Then .End = .End - 1
    ' If the numbers are input right-to-left, use:
    StrTmp = Reverse(.Text)
    ' If the numbers are input left-to-right, use:
    StrTmp = .Text
    For i = 0 To 9
      ' For arabic #s, use 1632
      StrTmp = Replace(StrTmp, ChrW(1632 + i), Chr(48 + i))
      ' For persian #s, use 1776
      StrTmp = Replace(StrTmp, ChrW(1776 + i), Chr(48 + i))
    Next i
    .Text = StrTmp
    .Collapse (wdCollapseEnd)
  Loop
End With
End Sub

Function Reverse(StrTmp As String) As String
  If (Len(StrTmp) > 1) Then
    Reverse = Reverse(Mid$(StrTmp, 2)) + Left$(StrTmp, 1)
  Else
    Reverse = StrTmp
  End If
End Function