Automatic - Appendix? Listing of Hyperlinks

[AKS0305]

Hi,

I am trying to create a policies and procedure manual for my work. So far there is an Automatic TOC (Chapters)
Automatic Table of Figures (Listing of Tables / Charts or Screenshots)

In a separate type of automated process, I would like to create an Appendix type of document listing, which will list all of the varying links to outside sources or within our company, so that I will have one list to update from as we update every several months various documents that are listed in this document. I cannot seem to find a way to do this. I currently, have started using a new style for the links that I would like to list in hopes that I will find a way to integrate that style into this. I am sure its just something I am missing and that there must be a way.

I currently use MS Word for Mac 2016

[Charles Kenyon]

You are not just missing something. What you have specified is not a built-in Word option.


You could use the index feature to prepare a list of the links. This would be far from Automatic.
Indices - Complex Documents

[macropod]

You could use a macro like:

Sub Demo()
Dim RngDoc As Range, RngOut As Range, Fld As Field
With ActiveDocument
  .Range.InsertAfter vbCr & Chr(12)
  Set RngDoc = .Range
  RngDoc.End = RngDoc.End - 2
  Set RngOut = .Characters.Last
  For Each Fld In RngDoc.Fields
    Select Case Fld.Type
      Case wdFieldData, wdFieldDatabase, wdFieldDDE, wdFieldDDEAuto, wdFieldImport, _
        wdFieldInclude, wdFieldIncludePicture, wdFieldIncludeText, wdFieldRefDoc
        With RngOut
          .InsertAfter vbCr
          .Characters.Last.Text = Fld.LinkFormat.SourceFullName
        End With
      Case wdFieldHyperlink
        With RngOut
          .InsertAfter vbCr
          .Characters.Last.FormattedText = Fld.Result.FormattedText
        End With
    End Select
  Next
  RngOut.Collapse wdCollapseStart
  RngOut.Text = "External Links"
End With
End Sub

Hyperlinks are retained as such; in all other cases, the list simply indicates the path & name of the source file.

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
For Mac macro installation & usage instructions, see: https://wordmvp.com/Mac/InstallMacro.html

[AKS0305]

Thank you so much. I was thinking this might be the case, and wanted to double check with the experts.