Need help in MS Word 2013

[Tkash]

I am currently working on a new translation of the bible and the verse numbers are all in bold in 12 pt font and the text is in regular 12 point font. I want to know if there is a way to change all bold text to a smaller font without going through 1800 pages. thanks Tkash

[macropod]

In Bible texts, verse numbers are usually superscripted. Sometimes, when not superscripted, they have [] around them. The following macro will superscript all such numbers and delete the [] if present.

Sub Verses()
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  With .Replacement.Font
    .Bold = True
    .Superscript = True
  End With
  .Forward = True
  .Wrap = wdFindStop
  .Format = True
  .MatchWildcards = True
  .Text = "\[([0-9]{1,3})\]"
  .Replacement.Text = "\1"
  .Execute Replace:=wdReplaceAll
  .Text = "([0-9]{1,3})"
  .Execute Replace:=wdReplaceAll
End With
End Sub

Of course, if you have chapter & book numbers as well, you might not want those superscripted. Without knowing more about your document structure, though, I can't offer more than to suggest changing 'ActiveDocument' in the code to 'Selection' and selecting each range you want to process.

[Tkash]

I could send you a sample of what I am doing if you wish

[macropod]

You could attach a document with a few short numbered books & chapters (e.g. 1 & 2 Thessalonians) so I can see what you're working with. You do this via the paperclip symbol on the 'Go Advanced' tab at the bottom of this screen.

[Tkash]

This is a sample of what I am dealing with. Any advice will be much appreciated. thanks
Terry

[macropod]

Try the following macro:

Sub FormatVerses()
Application.ScreenUpdating = False
Dim Rng As Range
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^13Chapter [0-9]{1,3}^13"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    Set Rng = .Duplicate.Characters.Last
    Rng.End = ActiveDocument.Range.End
    With .Duplicate
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "^13Chapter [0-9]{1,3}^13"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchWildcards = True
        .Execute
      End With
      If .Find.Found Then Rng.End = .Start
      With Rng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Format = False
        .Forward = True
        .Wrap = wdFindStop
        .MatchWildcards = True
        .Text = "([! ^13])([0-9]{1,3})"
        .Replacement.Text = "\1 \2"
        .Execute Replace:=wdReplaceAll
        .Text = "([0-9]{1,3})[ " & Chr(160) & "]"
        .Replacement.Text = "\1"
        .Execute Replace:=wdReplaceAll
        .Text = "[0-9]{1,3}"
        .Replacement.Text = "^&" & Chr(160)
        .Format = True
        With .Replacement.Font
          .Bold = True
          .Superscript = True
        End With
        .Execute Replace:=wdReplaceAll
      End With
    End With
    .Find.Execute
  Loop
End With
Set Rng = Nothing
Application.ScreenUpdating = True
End Sub

With the above code, all your chapter verses will be formatted as superscript bold with an ordinary space before and a non-breaking space after.

[Tkash]

HI Paul not sure How to put the code in???

[macropod]

For macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm