Need help in MS Word 2013

Tkash · #1 03-30-2014, 04:18 PM

I am currently working on a new translation of the bible and the verse numbers are all in bold in 12 pt font and the text is in regular 12 point font. I want to know if there is a way to change all bold text to a smaller font without going through 1800 pages. thanks Tkash

macropod · #2 03-30-2014, 06:52 PM

In Bible texts, verse numbers are usually superscripted. Sometimes, when not superscripted, they have [] around them. The following macro will superscript all such numbers and delete the [] if present.

Code:

Sub Verses()
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  With .Replacement.Font
    .Bold = True
    .Superscript = True
  End With
  .Forward = True
  .Wrap = wdFindStop
  .Format = True
  .MatchWildcards = True
  .Text = "\[([0-9]{1,3})\]"
  .Replacement.Text = "\1"
  .Execute Replace:=wdReplaceAll
  .Text = "([0-9]{1,3})"
  .Execute Replace:=wdReplaceAll
End With
End Sub

Of course, if you have chapter & book numbers as well, you might not want those superscripted. Without knowing more about your document structure, though, I can't offer more than to suggest changing 'ActiveDocument' in the code to 'Selection' and selecting each range you want to process.

Tkash · #3 03-30-2014, 08:52 PM

I could send you a sample of what I am doing if you wish

macropod · #4 03-30-2014, 09:27 PM

You could attach a document with a few short numbered books & chapters (e.g. 1 & 2 Thessalonians) so I can see what you're working with. You do this via the paperclip symbol on the 'Go Advanced' tab at the bottom of this screen.

Tkash · #5 03-31-2014, 08:17 AM

This is a sample of what I am dealing with. Any advice will be much appreciated. thanks
Terry

macropod · #6 03-31-2014, 05:20 PM

Try the following macro:

Code:

Sub FormatVerses()
Application.ScreenUpdating = False
Dim Rng As Range
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^13Chapter [0-9]{1,3}^13"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    Set Rng = .Duplicate.Characters.Last
    Rng.End = ActiveDocument.Range.End
    With .Duplicate
      With .Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = "^13Chapter [0-9]{1,3}^13"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindStop
        .Format = False
        .MatchWildcards = True
        .Execute
      End With
      If .Find.Found Then Rng.End = .Start
      With Rng.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Format = False
        .Forward = True
        .Wrap = wdFindStop
        .MatchWildcards = True
        .Text = "([! ^13])([0-9]{1,3})"
        .Replacement.Text = "\1 \2"
        .Execute Replace:=wdReplaceAll
        .Text = "([0-9]{1,3})[ " & Chr(160) & "]"
        .Replacement.Text = "\1"
        .Execute Replace:=wdReplaceAll
        .Text = "[0-9]{1,3}"
        .Replacement.Text = "^&" & Chr(160)
        .Format = True
        With .Replacement.Font
          .Bold = True
          .Superscript = True
        End With
        .Execute Replace:=wdReplaceAll
      End With
    End With
    .Find.Execute
  Loop
End With
Set Rng = Nothing
Application.ScreenUpdating = True
End Sub

With the above code, all your chapter verses will be formatted as superscript bold with an ordinary space before and a non-breaking space after.

Tkash · #7 03-31-2014, 10:03 PM

HI Paul not sure How to put the code in???

macropod · #8 04-01-2014, 01:32 AM

For macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Word 2013: Hyperlinks in word created pdf open in web browser and not acrobat reader	slaycock	Word	5	03-08-2014 01:04 PM
Word 2013	cday	Word	4	01-16-2014 11:58 AM
Word 2013 vs Word 2010 formatting issue?	rhoyt	Word	1	12-07-2013 09:40 AM
Are user customizations transferable from Word 2003 to Word 2010 (2013)?	New Daddy	Word	3	01-14-2013 07:25 AM
Which ODF/ .odt version is word 2010, 2013 preview & eventually 2013 full using?	semiotically	Word	8	11-08-2012 05:44 PM