Wanted: Printable List of Built-in Word styles

[sbianco]

Where can I find a table containing all the Built-in style names (Body text, caption, header 8, List Number 4, etc), maybe a description brief (normal + tabs: 3" Centered, etc) and most importantly a brief when to use (numbered, subheader, comments, have indents, table cell, etc). Thanks OOPs, for 2010

[macropod]

Try the following macro in an empty document:

Sub GetBuiltinParaStyleDefs()
Dim oSty As Style, StrSty As String, TbStp As TabStop, SngTab As Single
With ActiveDocument
  For Each oSty In .Styles
    With oSty
      StrSty = ""
      If .BuiltIn = True Then
        If .Type = wdStyleTypeParagraph Then
          With .ParagraphFormat
            StrSty = "Style: " & ActiveDocument.Styles(oSty).NameLocal & vbTab
            StrSty = StrSty & StrSty & "Alignment: " & .Alignment
            StrSty = StrSty & Chr(11) & "Font: " & ActiveDocument.Styles(oSty).Font.Name
            If ActiveDocument.Styles(oSty).Font.Bold = True Then StrSty = StrSty & " (Bold)"
            StrSty = StrSty & vbTab & "Size: " & ActiveDocument.Styles(oSty).Font.Size
            StrSty = StrSty & Chr(11) & "First Line Indent: " & PointsToInches(.FirstLineIndent)
            StrSty = StrSty & Chr(11) & "Right Indent: " & PointsToInches(.RightIndent)
            StrSty = StrSty & Chr(11) & "Left Indent: " & PointsToInches(.LeftIndent)
            StrSty = StrSty & Chr(11) & "Space After: " & PointsToInches(.SpaceAfter)
            StrSty = StrSty & Chr(11) & "Space Before: " & PointsToInches(.SpaceBefore)
            For Each TbStp In .TabStops
              StrSty = StrSty & Chr(11) & "TabStop Alignment: "
              Select Case TbStp.Alignment
                Case 0: StrSty = StrSty & "Left"
                Case 1: StrSty = StrSty & "Center"
                Case 2: StrSty = StrSty & "Right"
                Case 3: StrSty = StrSty & "Decimal"
                Case 4: StrSty = StrSty & "Bar"
                Case 6: StrSty = StrSty & "List"
              End Select
              StrSty = StrSty & " @ " & PointsToInches(TbStp.Position)
            Next
            StrSty = StrSty & vbCr
          End With
        End If
      End If
    End With
    .Range.InsertAfter StrSty
  Next
End With
End Sub

This will output a list of all the paragraph Styles in your document, with their basic attributes.

For installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm

[sbianco]

I ran the macro; works perfect, now if you could add a general description of the purpose of each of those styles that would be good. Anyways Thanks and I now I know how to run macros in Office.

[Charles Kenyon]

Originally Posted by sbianco

I ran the macro; works perfect, now if you could add a general description of the purpose of each of those styles that would be good. Anyways Thanks and I now I know how to run macros in Office.

This is an excellent question, but, I'm sorry, I think you are expecting a bit too much, like mind reading, from a vba program. Descriptions of uses of the built-in styles fill many pages. Most are semi-undocumented. Styles are at the heart of Word and understanding them is crucial to using Word well. It is just that I don't think a vba program can do much to shortcut what you'll have to learn.

The purposes of styles are determined by the person who creates it. See Understanding Styles in Microsoft Word
Why use Microsoft Word’s built-in heading styles?
Tips for Understanding Styles in Word
How to create numbered headings or outline numbering in Word 2007 and Word 2010
3. Use styles to format text
5. Use a bulleted paragraph style for bullets and dotpoints
What happens when I send my document to someone else? Will Word mess up my formatting?
How to control the Quick Styles gallery on the Home tab in Word

I would recommend getting a good book and starting with that.
Ø Microsoft Word 2010 Bible by Herb Tyson
Ø Microsoft Word 2010 In Depth by Faithe Wempen
Ø Microsoft Word 2010 Inside Out by Katherine Murray

Ø Microsoft Word 2010: The Missing Manual by Nancy Connor and Matthew McDonald

[macropod]

There is no such thing as a "general description of the purpose of each of those styles". You can use them for whatever purpose you like. Furthermore, you can change their formatting to almost whatever you like so that you can completely re-purpose most of them.