Determining file path for linked image in Word 2007

macropod · #4 03-27-2012, 02:53 PM

Hi samhdc,

Possibly so. Here's a macro to do the job:

Code:

Sub UpdateObjPath()
Dim StrPath As String, Resp
With Selection
  If .InlineShapes.Count > 0 Then
    With .InlineShapes(1)
      If Not .LinkFormat Is Nothing Then
        While Dir(StrPath) = ""
          Resp = InputBox("Please input the new path & name" & vbCr & _
            "for the first selected inline object", _
            "Link Updater", .LinkFormat.SourceFullName)
          If Resp = "" Then Exit Sub
          StrPath = Resp
        Wend
        .LinkFormat.SourceFullName = StrPath
      Else
        MsgBox "The first selected inline object is embedded, not linked."
      End If
    End With
  ElseIf .ShapeRange.Count > 0 Then
    With .ShapeRange(1)
      If Not .LinkFormat Is Nothing Then
        While Dir(StrPath) = ""
          Resp = InputBox("Please input the new path & name" & vbCr & _
            "for the first selected floating object", _
            "Link Updater", .LinkFormat.SourceFullName)
          If Resp = "" Then Exit Sub
          StrPath = Resp
        Wend
        .LinkFormat.SourceFullName = StrPath
      Else
        MsgBox "The first selected floating object is embedded, not linked."
      End If
    End With
  Else
    MsgBox "No object selected"
  End If
End With
End Sub

Note: The code works for any embedded/linked object, not just pictures, and allows you to update the path & name.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
how to get image in clip draw by giving path	gsrikanth	Office	0	03-22-2012 05:03 AM
File Path for Outlook 2007 pst	eliz.bell	Outlook	2	10-29-2011 07:04 PM
Display Full File Path Name of Document in Title bar MS-Word 2010	Carlos06x	Word	1	10-12-2011 10:39 AM
Excel File as Linked Object in Word	jfitch	Word	0	03-18-2010 11:44 AM
Programmatically get File Path for currently opened WORD document	franferns	Word	1	11-26-2009 12:36 PM