Sub MarginTextStyle()
Dim styleName As String
Dim oStyle As Style
  styleName = "Margin Text"
  'Create/Setup the style
  For Each oStyle In ActiveDocument.Styles
    If oStyle.NameLocal = styleName Then GoTo Setup
  Next oStyle
  ActiveDocument.Styles.Add Name:=styleName, Type:=wdStyleTypeParagraph
Setup:
  With ActiveDocument.Styles(styleName)
    .AutomaticallyUpdate = False
    .BaseStyle = ""
    .NextParagraphStyle = "Normal"
  End With
  With ActiveDocument.Styles(styleName).Font
    .Size = 8
    .ColorIndex = wdAuto
  End With
  With ActiveDocument.Styles(styleName).ParagraphFormat
    .LineSpacingRule = wdLineSpaceSingle
    .SpaceAfter = 0
    .WidowControl = False
    .KeepWithNext = True
    .KeepTogether = True
    .OutlineLevel = wdOutlineLevelBodyText
    .Shading.BackgroundPatternColor = wdColorLightYellow
    With .Borders
      .OutsideLineStyle = wdLineStyleSingle
      .OutsideLineWidth = wdLineWidth050pt
      .OutsideColor = wdColorAutomatic
      .DistanceFromTop = 1
      .DistanceFromLeft = 1
      .DistanceFromBottom = 1
      .DistanceFromRight = 1
      .Shadow = False
    End With
  End With
  With ActiveDocument.Styles(styleName).Frame
    .TextWrap = True
    .WidthRule = wdFrameExact
    'Accomodate 1" margin.   Adjust to suit,
    .Width = 55
    .HeightRule = wdFrameAuto
    .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
    .RelativeVerticalPosition = wdRelativeVerticalPositionParagraph
    .HorizontalDistanceFromText = InchesToPoints(0.08)
    .VerticalDistanceFromText = InchesToPoints(0)
    .LockAnchor = False
  End With
lbl_Exit:
  Exit Sub
End Sub

Sub ApplyMarginTextToSty1()
Dim oRng As Range
Dim oRngDef As Range
Dim strDef As String
  Set oRng = ActiveDocument.Range
  With oRng.Find
    .Style = "Sty1"
    While .Execute
      If oRng.Start = oRng.Paragraphs(1).Range.Start And oRng.End = oRng.Paragraphs(1).Range.End Then
        oRng.Style = "Margin Text"
      Else
        strDef = oRng.Text
        oRng.Delete
        Set oRngDef = oRng.Paragraphs(1).Range
        oRngDef.Start = oRngDef.Paragraphs(1).Range.Start
        oRngDef.InsertBefore vbCr
        oRngDef.Paragraphs.First.Style = "Margin Text"
        oRngDef.Paragraphs.First.Range.Text = strDef
      End If
    Wend
  End With
lbl_Exit:
  Exit Sub
End Sub