Sub Find_JumpToNextCrossReference()
'Method A
Dim oRng As Range
Dim oFld As Field
  Set oRng = Selection.Range.Duplicate
  oRng.End = ActiveDocument.Range.End
  If ActiveDocument.Fields.Count > 0 Then
LoopToStart:
  If oRng.Fields.Count > 0 Then
    If oRng.Fields.Count = 1 And oRng.Fields(1).Result.Start = oRng.Start Then
      oRng.Start = oRng.Fields(1).Result.End + 1
      If MsgBox("This is the last REF field. Do you want to loop to the beginning of the document?,", vbQuestion + vbYesNo, "LOOP") = vbYes Then
        oRng.Start = ActiveDocument.Range.Start
      End If
    End If
    For Each oFld In oRng.Fields
      If oFld.Type = wdFieldRef Then
        If oFld.Result.Start > oRng.Start Then
          oFld.Result.Select
          Exit For
        End If
      End If
    Next oFld
    If oRng.Start = Selection.Range.Start Then
      MsgBox "There are no REF fields in the document.", vbInformation + vbOKOnly, "NO CROSS REFERENCES FOUND"
    End If
  Else
    If MsgBox("There is no subsequent REF field in this document. Do you want to loop to the beginning of the document?", vbQuestion + vbYesNo, "LOOP FROM START") = vbYes Then
      oRng.Start = ActiveDocument.Range.Start
      GoTo LoopToStart
    End If
  End If
  Else
     MsgBox "There are no REF fields in this document.", vbInformation + vbOKOnly, "NO CROSS REFERENCES FOUND"
  End If
lbl_Exit:
  Exit Sub
End Sub

Sub GoToNextREFField()
'Method B
Dim lngStart As Long
Dim lngCount As Long
Dim lngFldCount As Long
Dim oRngRef As Range, oRng As Range
  Application.ScreenUpdating = False
  Set oRngRef = Selection.Range.Duplicate
  lngFldCount = ActiveDocument.Fields.Count
LoopToStart:
  lngCount = 0
  Do
    Set oRng = Selection.Range.Duplicate
    lngStart = Selection.Range.Start
    Selection.GoToNext (wdGoToField)
    'Get field in selection
    Selection.MoveEnd , 1
    lngCount = lngCount + 1
    If Selection.Start = oRng.Start Then Exit Do
  Loop Until Selection.Fields(1).Type = wdFieldRef
  Select Case True
    Case lngCount > lngFldCount And Selection.Fields.Count = 0
      MsgBox "There are no REF fields in the document.", vbInformation + vbOKOnly, "NOTHING TO GOTO"
    Case lngCount > lngFldCount And Selection.Fields(1).Type <> wdFieldRef
      MsgBox "There are no REF fields in the document.", vbInformation + vbOKOnly, "NOTHING TO GOTO"
      oRngRef.Select
    Case Selection.Fields(1).Type <> wdFieldRef Or (Selection.Start = oRngRef.Start And Selection.Fields(1).Type = wdFieldRef)
     If MsgBox("There is no subsequent REF field in this document." & vbCr + vbCr _
         & "Do you want to loop to the start of the document?", vbInformation + vbYesNo, "LOOP") = vbYes Then
         ActiveDocument.Range(0, 0).Select
         GoTo LoopToStart
      Else
        oRngRef.Select
      End If
  End Select
Application.ScreenUpdating = True
lbl_Exit:
  Exit Sub
End Sub

Sub FindMeSeymour()
  ActiveWindow.View.ShowFieldCodes = True
  With Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^d REF"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .MatchCase = False
    .Execute
  End With
  ActiveWindow.View.ShowFieldCodes = False
End Sub

Sub FieldJumper()
  JumpToTypeField "REF", False
End Sub
Sub JumpToTypeField(strType As String, Optional bNext As Boolean = True)
'Method C
Dim oRng As Range, oRngRef As Range
Dim bShowCodes As Boolean
Dim lngFind As Long, lngCount As Long
Dim strMsg As String
  lngCount = 0
  lngFind = 0
  Set oRng = ActiveDocument.Range
  bShowCodes = ActiveWindow.View.ShowFieldCodes
  ActiveWindow.View.ShowFieldCodes = True
  With oRng.Find
    .ClearFormatting
    .Text = "^d " & strType
    .Forward = bNext
    .Wrap = wdFindStop
    .MatchCase = False
    Do While .Execute
      lngCount = lngCount + 1
      If lngCount > 1 Then Exit Do
    Loop
  End With
Wrap:
  Set oRng = Selection.Range.Duplicate
  Select Case lngCount
    Case 0
      MsgBox "There are no " & strType & " fields in this document.", vbInformation + vbOKOnly, "NOT FOUND"
    Case Else
      With oRng.Find
        .ClearFormatting
        .Text = "^d " & strType
        .Forward = bNext
        .Wrap = lngFind
        .MatchCase = False
        If .Execute Then
          oRng.Select
        Else
          If lngCount > 1 Or Selection.Fields.Count = 0 Then
            ActiveWindow.View.ShowFieldCodes = False
            strMsg = "There are no subsequent " & strType & " fields in the document. Do you want to loop to the beginning of the document?"
            If Not bNext Then strMsg = "There are no preceding " & strType & " fields in the document. Do you want to loop to the end of the document?"
            If MsgBox(strMsg, vbQuestion + vbYesNo, "LOOP") = vbYes Then
              lngFind = 1
              ActiveWindow.View.ShowFieldCodes = True
              GoTo Wrap
            End If
          Else
            ActiveWindow.View.ShowFieldCodes = False
            MsgBox "There are no preceding or subsequent " & strType & " fields in this document.", vbInformation + vbOKOnly, "SINGULAR FIELD"
          End If
        End If
      End With
    End Select
lbl_Exit:
  ActiveWindow.View.ShowFieldCodes = bShowCodes
  Exit Sub
End Sub