Microsoft Office Forums

Go Back   Microsoft Office Forums > >

Reply
 
Thread Tools Display Modes
  #1  
Old 12-19-2022, 11:38 PM
Guessed's Avatar
Guessed Guessed is offline insertbefore in all cells and columns Windows 10 insertbefore in all cells and columns Office 2016
Expert
 
Join Date: Mar 2010
Location: Canberra/Melbourne Australia
Posts: 4,176
Guessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant futureGuessed has a brilliant future
Default

Any query on .Rows will throw an error if there are vertical merges. Similarly, .Columns will error if there is a horizontal merge. Perhaps this is what you are trying to do


Code:
Sub InsertTableTags()
  Dim tbl As Table, aCell As Cell
  Dim iRow As Integer, iCol As Integer, iRows As Integer
  
  ' Loop through all tables in the document
  For Each tbl In ActiveDocument.Tables
    iRows = tbl.Rows.Count
    For Each aCell In tbl.Range.Cells
      iRow = aCell.RowIndex
      iCol = aCell.ColumnIndex
      Debug.Print iRow, iCol, aCell.Range.Words(1)
      Select Case iRow
        Case 1
          'do nothing
        Case 2
          'If aCell.Next.RowIndex <= iRow Then    'not sure if you want to manage merged
            aCell.Range.InsertBefore Text:="<TC>"
          'End If
        Case iRows    'last row only
          If aCell.Range.Text Like "*Source*" Or aCell.Range.Text Like "*Note*" Then
            aCell.Range.InsertBefore Text:="<TTS>"
          Else
            aCell.Range.InsertBefore Text:="<TTL>"
          End If
        Case Else  'not first, second or last row
          aCell.Range.InsertBefore Text:="<TT>"
      End Select
    Next aCell
  Next tbl
End Sub
__________________
Andrew Lockton
Chrysalis Design, Melbourne Australia
Reply With Quote
Reply



Similar Threads
Thread Thread Starter Forum Replies Last Post
insertbefore in all cells and columns sorting cells in excel into specific columns oscarlimerick Excel 6 05-11-2022 07:26 AM
insertbefore in all cells and columns Problem with merged cells and row height in adjacent two- and three-row columns rolandoftheeld Word Tables 3 08-31-2018 03:55 PM
insertbefore in all cells and columns Relating cells in a row in one sheet to cells in columns on another sheet. mbesspiata3 Excel 2 01-06-2017 05:42 AM
Insertbefore an array? help :( n00bie-n00b Word VBA 21 08-21-2014 08:03 PM
How to merge two columns & replace contents of cells conditionally? mag Excel 3 10-24-2012 01:07 PM

Other Forums: Access Forums

All times are GMT -7. The time now is 01:36 AM.


Powered by vBulletin® Version 3.8.11
Copyright ©2000 - 2025, vBulletin Solutions Inc.
Search Engine Optimisation provided by DragonByte SEO (Lite) - vBulletin Mods & Addons Copyright © 2025 DragonByte Technologies Ltd.
MSOfficeForums.com is not affiliated with Microsoft