Insert multiple pictures at once in Word table

Guessed · #1 11-29-2022, 04:15 PM

At its most basic, assume your PNGs are all in the same folder as the Word document. Then this code will iterate through a column of text to add the corresponding image in the preceding cell

Code:

Sub InsertImages()
  Dim aCell As Cell, sPath As String, sFile As String, aTbl As Table, iCol As Integer
  Dim aRng As Range, aShp As InlineShape
  
  Set aTbl = Selection.Tables(1)
  iCol = Selection.Cells(1).Column.Index
  sPath = ActiveDocument.Path & Application.PathSeparator
  For Each aCell In aTbl.Columns(iCol).Cells
    sFile = sPath & Split(aCell.Range.Text, vbCr)(0) & ".png"
    If Len(Dir(sFile)) > 0 Then
      Debug.Print sFile
      Set aRng = aCell.Previous.Range
      Set aShp = ActiveDocument.InlineShapes.AddPicture(FileName:=sFile, Range:=aRng)
      aShp.AlternativeText = sFile
      aShp.Width = CentimetersToPoints(0.8)
      aShp.Height = CentimetersToPoints(0.8)
      aRng.Cells(1).VerticalAlignment = wdCellAlignVerticalCenter
      aRng.Cells(1).Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
    End If
  Next aCell
End Sub

elias17 · #2 11-30-2022, 06:46 AM

Hi Andrew,

thank you very much for the code, it works perfectly!

Just one thing: the images are inserted with the layout option "In Line with Text" but I would need them to be "In Front of Text". Would this be possible?
Screenshot 3.png

Thanks,
Elias

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Mac - Macro insert pictures in table	Nina	Word VBA	16	08-27-2018 01:53 AM
Macro to insert multiple pictures with adjustable column size	nando88	Word VBA	6	05-09-2016 11:56 PM
Insert an article with pictures into a table cell	skatiemcb	Word Tables	2	01-24-2015 08:18 AM
Macro to insert multiple pictures to word to a specific size and text wrap	mescaL	Word VBA	3	11-03-2014 10:51 PM
Resize multiple pictures in a Word 2010 table	JBA479	Word VBA	1	01-24-2014 08:51 PM