Hide one bookmark when Two checkboxes are checked

AVarg123 · #1 03-30-2022, 04:22 PM

Hello, How can I hide a bookmark when two checkboxes are checked. I have checkbox1 and checkbox2. If both are checked then the bookmark "test" should be hidden. How can I do this using word VBA? Really appreciate any help. Thank you!

Guessed · #2 03-30-2022, 09:38 PM

What type of checkbox are you using?

AVarg123 · #3 03-31-2022, 10:54 AM

ActiveX Checkbox Control

gmayor · #4 03-31-2022, 08:51 PM

The following will do that, however you should be aware that if the font is hidden it can easily be un-hidden by anyone viewing the document in Word format. Change BMName to the name of the bookmark.

Code:

Private Sub CheckBox1_Click()
    ActiveWindow.View.ShowHiddenText = False
    If CheckBox1.Value = True And CheckBox2.Value = True Then
        ActiveDocument.Bookmarks("BMName").Range.Font.Hidden = True
    Else
        ActiveDocument.Bookmarks("BMName").Range.Font.Hidden = False
    End If
End Sub

Private Sub CheckBox2_Click()
    ActiveWindow.View.ShowHiddenText = False
    If CheckBox1.Value = True And CheckBox2.Value = True Then
        ActiveDocument.Bookmarks("BMName").Range.Font.Hidden = True
    Else
        ActiveDocument.Bookmarks("BMName").Range.Font.Hidden = False
    End If
End Sub

Guessed · #5 04-01-2022, 06:21 PM

Graham gave you the solution already.

Note that there is a gotcha with the .ShowHiddenText - if the user has ShowAll then it doesn't matter about the showhiddentext. To deal with that and make the code a bit shorter...

Code:

Private Sub CheckBox1_Click()
  ActiveWindow.View.ShowHiddenText = False
  ActiveWindow.View.ShowAll = False
  ActiveDocument.Bookmarks("BMName").Range.Font.Hidden = CheckBox1.Value And CheckBox2.Value
End Sub

Private Sub CheckBox2_Click()
  CheckBox1_Click
End Sub

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Add / Sum checked Checkboxes labelled 1, 2, 3, etc. in Word Table - Need Macro?	klearazkrystal	Word VBA	7	03-31-2019 11:50 PM
Bookmark will not show/hide based on CC Checkbox	lord_kaiser	Word VBA	1	04-17-2018 01:19 AM
Need Macro to select Checkbox after two boxes are checked in a series of checkboxes	rsaini	Word VBA	0	01-16-2018 11:57 AM
Hide error message from missing bookmark	lodi123	Word	2	03-28-2017 11:24 PM
Checkboxes are unchecked in Listbox that were checked off before.How can I stop this?	Rochelle711	Excel Programming	0	06-22-2014 06:16 PM