Split the heading number and text

[kamkwok6]

In the document, all lines are in "Heading" style


Sample question .docx
Sample question.jpg
I am looking for a single click to split my selection into heading number, and put the "heading text" into next line.

After that, remain the "heading number" in "Heading" style
and change the 'heading text" to "Normal" Style.

Final outcome as below, Many thanks!!!
Sample (Final Outcome).docx

[gmayor]

The following should work, based on your example:

Sub Macro1()
Dim oRng As Range
Dim oPara As Paragraph
Dim i As Integer
    If Len(Selection.Range) = 0 Then
        MsgBox "Nothing selected", vbCritical
        Exit Sub
    End If
    For i = Selection.Paragraphs.Count To 1 Step -1
        Set oPara = ActiveDocument.Paragraphs(i)
        If oPara.Range.Style Like "Heading #" Then
            Set oRng = oPara.Range
            oRng.Collapse 0
            oRng.MoveEndUntil Chr(9)
            oRng.End = oRng.End + 1
            oRng.Collapse 0
            oRng.Text = vbCr
            Set oRng = oRng.Next.Paragraphs(1).Range
            oRng.Style = "Normal"
        End If
    Next i
lbl_Exit:
    Set oPara = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub

[kamkwok6]

Thank you for the reply, however I still have some question when using your code.

When I select "7.23.7.7" and then run your code.
Sample question2.jpg

The effect was made on "7.11.7"
Sample question3.jpg

[gmayor]

OK, try the following instead

Sub Macro1()
Dim oRng As Range
Dim oPara As Paragraph
    If Len(Selection.Range) = 0 Then
        MsgBox "Nothing selected", vbCritical
        Exit Sub
    End If
    For Each oPara In Selection.Paragraphs
        If oPara.Range.Style Like "Heading #" Then
            Set oRng = oPara.Range
            oRng.Collapse 1
            oRng.MoveEndUntil Chr(9)
            oRng.End = oRng.End + 1
            oRng.Collapse 0
            oRng.Text = vbCr
            Set oRng = oRng.Next.Paragraphs(1).Range
            oRng.Style = "Normal"
        End If
    Next oPara
lbl_Exit:
    Set oPara = Nothing
    Set oRng = Nothing
    Exit Sub
End Sub