Private Sub Tools_Text_Format_TeamCenter_Document_Numbers()
'
' find teamcenter document numbers and format them
'
' https://regex101.com/
'
    Dim arrFindReplaceExpressions()
    Dim varCounter As Variant

    arrFindReplaceExpressions = Array("<([0-9A-Z]{4}[.])([0-9A-Z]{7}[.])([0-9A-Z]{3}[.])([0-9A-Z.]{4})>", _
                                      "<([0-9A-Z]{4}[.])([0-9A-Z]{7}[.])([0-9A-Z]{3}[.])([0-9A-Z.]{2})>", _
                                      "<([0-9]{8}[.])([0-9A-Z]{3}[.])([A-Z]{2})>")
    
    For Each varCounter In arrFindReplaceExpressions
        Selection.Find.ClearFormatting
        Selection.Find.Replacement.ClearFormatting
        With Selection.Find
            '.Replacement.Text = ""
            .Text = varCounter
            .Replacement.Font.Bold = True
            .Forward = True
            .Wrap = wdFindContinue
            .Format = True
            .MatchCase = False
            .MatchWholeWord = False
            .MatchAllWordForms = False
            .MatchSoundsLike = False
            .MatchWildcards = True ' needed for special characters, otherwise they're treated as ordinary text
            .Execute Replace:=wdReplaceAll
        End With
    Next varCounter
    
    Set varCounter = Nothing
    Erase arrFindReplaceExpressions
    
    Debug.Print "Finished!"
End Sub

Sub Demo()
Application.ScreenUpdating = False
Dim Rng As Range
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "<[A-Z0-9.\-]@[A-Z0-9.\-]@[DE]*>"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
  End With
  Do While .Find.Execute
    Set Rng = .Duplicate
    With Rng
      .End = .Paragraphs(1).Range.End - 1
      .End = .Start + Len(Split(.Text, " ")(0))
      .Collapse wdCollapseEnd
      .End = .Paragraphs(1).Range.End - 1
      If UBound(Split(.Text, " ")) > 1 Then
        If Split(.Text, " ")(1) = "REV" Then .End = .Start + 10
      End If
    End With
    .End = Rng.End
    .Font.Bold = True
    .Collapse wdCollapseEnd
  Loop
End With
Application.ScreenUpdating = True
End Sub