Notepad to Word : Pasting Specific text ie between any two blank line from notepad to word

macropod · #4 01-16-2021, 10:56 PM

If the aim is simply to write all the non-empty lines to the active document, you could use code like:

Code:

Sub Demo1()
Application.ScreenUpdating = False
Dim DocSrc As Document, DocTgt As Document
Set DocTgt = ActiveDocument: Set DocSrc = Documents.Open(FileName:="C:\Text-To-MsWord\Sample.txt", AddToRecentFiles:=False, Visible:=False)
With DocSrc
  With .Range
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Format = False
      .Forward = True
      .Wrap = wdFindContinue
      .MatchWildcards = True
      .Text = "[^13]"
      .Replacement.Text = "^p"
      .Execute Replace:=wdReplaceAll
      .Text = "[^13]{2,}"
      .Execute Replace:=wdReplaceAll
    End With
    DocTgt.Range.Characters.Last.Text = .Text
  End With
  .Close False
End With
Application.ScreenUpdating = True
End Sub

Alternatively, if the aim is to write only the content between the first & second set of empty lines to the active document, you could use code like:

Code:

Sub Demo()
Application.ScreenUpdating = False
Dim DocSrc As Document, DocTgt As Document
Set DocTgt = ActiveDocument: Set DocSrc = Documents.Open(FileName:="C:\Text-To-MsWord\Sample.txt", AddToRecentFiles:=False, Visible:=False)
With DocSrc
  With .Range
    With .Find
    .Format = False
    .Forward = True
    .Wrap = wdFindContinue
    .MatchWildcards = True
    .Text = "[^13]"
    .Replacement.Text = "^p"
    .Execute Replace:=wdReplaceAll
      .Wrap = wdFindStop
      .MatchWildcards = True
      .Text = "[^13]{2}[!^13]*[^13]{2}"
      .Replacement.Text = "^p"
      .Execute
    End With
    If .Find.Found = True Then
      DocTgt.Range.Characters.Last.Text = Replace(.Text, vbCr & vbCr, "")
    End If
  End With
  .Close False
End With
Application.ScreenUpdating = True
End Sub

In either case, it is not necessary to know the start/end empty line positions.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Need help to get data from notepad to word	ganesang	Word VBA	2	08-11-2019 10:21 PM
Word does not stop at the set tab, but it keeps forever on the same line like it would in Notepad.	danvina@gmail.com	Word	2	01-16-2019 02:33 PM
Microsoft notepad over word for saving important text files	Noclip1	Word	1	10-25-2017 10:55 PM
Copy text with tab at start of line and paste to Notepad	JohnTurnbull	Word	5	08-27-2017 11:17 PM
Sr. Citizen Question, Please: WORD Shows Blank, But Notepad Shows "Gibberish" ?	Robert11	Word	3	08-12-2013 12:35 PM