Copy contents between parenthesis and paste to end of document

[jeffreybrown]

I found this code which will show me everything in the word document found between parenthesis. It shows in the Msgbox, but instead I would like to see the contents at the end of my document.

Sub FindInsideParanthesis()

    Dim myrange
    Set myrange = Application.ActiveDocument.Content

    Dim myFind
    Set myFind = myrange.Find

    While (myFind.Execute(FindText:="\(*\)", MatchWildcards:=True))

        'Process your tag here
        MsgBox (myrange.Text)

    Wend

End Sub

[macropod]

Try:

Sub FindInsideParanthesis()
Dim StrOut As String
With ActiveDocument
  With .Range
    With .Find
      .Text = "\(*\)"
      .MatchWildcards = True
      .Execute
    End With
    Do While .Find.Found = True
      'The next two lines exclude the start/end characters from what gets processed
      .Start = .Start + 1
      .End = .End - 1
      StrOut = StrOut & vbCr & .Text
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
  .Range.InsertAfter StrOut
End With
End Sub

[jeffreybrown]

Thank you Paul. This works great.