Removing headers from multiple files

rookieuk · #1 03-18-2019, 07:58 AM

Hi,

I'm trying to remove headers from multiple (thousands) of documents.

I've been trying to use the code provided by macropod in this thread - https://www.msofficeforums.com/word-...html#post62942 but I'm not having any success.

The header I'm trying to remove is defined as 'Different first page' and I don't know if that makes any difference. (copy of example file attached hopefully).

Basically all I want to do is remove that header completely and not have to do it manually across a few thousand files! Please help!

Thanks
Rookie

macropod · #2 03-18-2019, 02:15 PM

The code in that link is for replacing one header with another, using the document the macro is being run from as the source for the new headers. It is not written for deleting headers. Why are you trying to "remove headers from multiple (thousands) of documents"? In a commercial environment this could have serious adverse legal implications.

rookieuk · #3 03-19-2019, 02:01 AM

Thanks for replying.

The headers shouldn't be there in the first place. Each document file is imported into a master template which has the relevant headers/footers already in it. These other documents should be 'clean'.

The exercise I'm undertaking is to update certain information and due to the mistake of these headers being in these sub-documents, the scope is wildly inaccurate.

If you can help me strip out the headers completely that would be great!

Thanks
Rookie

macropod · #4 03-19-2019, 02:46 PM

Quote:

Originally Posted by rookieuk

The headers shouldn't be there in the first place. …

If you can help me strip out the headers completely that would be great!

In that case, change both instances of:

Code:

                            If .LinkToPrevious = False Then
                                .Range.FormattedText = _
                                wdDocSrc.Sections.First.Headers(wdHeaderFooterPrimary).Range.FormattedText
                            End If

to:

Code:

                            If .LinkToPrevious = False Then .Range.Text = vbNullString

gmayor · #5 03-19-2019, 04:52 AM

The following function will selectively delete headers and footers from the document. You could use it with http://www.gmayor.com/document_batch_processes.htm as a custom process to handle the folders containing the documents. Try it on a single example before running it on many documents to ensure that it deletes what is required in your documents.

Code:

Function DeleteHeaders(oDoc As Document) As Boolean
Dim oHeader As HeaderFooter
Dim oFooter As HeaderFooter
Dim oSection As Section
    On Error GoTo err_Handler

    For Each oSection In oDoc.Sections
        For Each oHeader In oSection.Headers
            If oHeader.Exists Then
                Select Case oHeader.Index
                    Case wdHeaderFooterFirstPage
                        'do nothing or oHeader.Range.Delete as required
                    Case wdHeaderFooterPrimary
                        oHeader.Range.Delete
                    Case wdHeaderFooterEvenPages
                        oHeader.Range.Delete
                End Select
            End If
        Next oHeader
        For Each oFooter In oSection.Footers
            If oFooter.Exists Then
                Select Case oFooter.Index
                    Case wdHeaderFooterFirstPage
                        'do nothing or oFooter.Range.Delete as required
                    Case wdHeaderFooterPrimary
                        oFooter.Range.Delete
                    Case wdHeaderFooterEvenPages
                        oFooter.Range.Delete
                End Select
            End If
        Next oFooter
    Next oSection
    DeleteHeaders = True
lbl_Exit:
    Set oSection = Nothing
    Set oHeader = Nothing
    Set oFooter = Nothing
    Exit Function
err_Handler:
    DeleteHeaders = False
    Resume lbl_Exit
End Function

Thread Tools
Show Printable Version Email this Page
Display Modes
Switch to Linear Mode Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Word 2010 removing headers from pages with photos	normancamp	Word	6	03-31-2018 02:39 PM
Removing Hyperlinks in Multiple Documents at Once	Jude24Joy	Word VBA	10	06-13-2017 05:38 AM
Removing Sections from headers and footers	Tonks811	Word	2	01-16-2016 10:30 PM
Updating headers in multiple files	cellophane	Word	3	01-17-2013 06:36 AM
convert multiple csv files to multiple excel files	mit	Excel	1	06-14-2011 10:15 AM