Check if named Content Control field exists and add missing

sylvio · #1 08-28-2017, 07:39 AM

Hello,

I am trying to code a macro which could check whether a document has all needed named content controls and add missing if necessary.
Let's say, the document should contain 3 CCs named "A", "B" and "C". If it contains only "A", the macro should add "B" and "C".

My code is below. It adds all CCs if some of the 3 named CC are missing, but do not differentiate which one should be added. How to add check for missing CCs?

Code:

Sub AddMissingCCs()
Dim CCnames
Dim i As Long
Dim j As Long
Dim CCcount As Long
Dim CCtrl As ContentControl

CCnames = Array("A", "B", "C")

For i = 0 To UBound(CCnames)
    For Each CCtrl In ActiveDocument.ContentControls
      If (UBound(Filter(CCnames, CCtrl.Title)) = -1) Then
        Selection.EndKey Unit:=wdStory
        ActiveDocument.Range.InsertAfter vbCr
        Selection.Range.ContentControls.Add (wdContentControlPlain)
        Selection.ParentContentControl.Title = CCnames(i)
       End If
    Next
Next

End Sub

macropod · #2 08-28-2017, 03:52 PM

Try:

Code:

Sub Demo()
Dim i As Long, ArrNames, CCtrl As ContentControl
ArrNames = Array("A", "B", "C")
With ActiveDocument
  For i = 0 To UBound(ArrNames)
    On Error Resume Next
    Set CCtrl = .SelectContentControlsByTitle(ArrNames(i))(1)
    On Error GoTo 0
    If CCtrl Is Nothing Then
      .Range.InsertAfter " "
      Set CCtrl = .ContentControls.Add(wdContentControlText, .Range.Characters.Last)
      CCtrl.Title = ArrNames(i)
    End If
    Set CCtrl = Nothing
  Next
End With
End Sub

sylvio · #3 08-29-2017, 04:08 AM

macropod, thank you very much!
It works as expected.

Thread Tools
Show Printable Version Email this Page
Display Modes
Linear Mode Switch to Hybrid Mode Switch to Threaded Mode

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Show field shading in Content Control	ajanson	Word	3	08-15-2016 04:49 PM
Have Text Entered in Content Control / PreDefined Field Populate Field in Footer	bzowk	Word	1	04-14-2016 11:50 AM
Check Box Content Control when checked users are presented with an option	cryder	Word	0	01-07-2016 05:11 AM
Replace checkbox symbol with check box content control	canadansk	Word VBA	5	04-01-2015 08:21 AM
Adding auto text to end of content control field	ksigcajun	Word VBA	4	10-13-2014 05:37 AM