Sub FixRefs()
Application.ScreenUpdating = False
ActiveWindow.View.ShowFieldCodes = True
With ActiveDocument
  Call FndRep(.Range)
  Call FndRep(.StoryRanges(wdEndnotesStory))
  Call FndRep(.StoryRanges(wdFootnotesStory))
End With
ActiveWindow.View.ShowFieldCodes = False
Application.ScreenUpdating = True
End Sub

Sub FndRep(Rng As Range)
With Rng
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "^d CITATION"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute
  End With
  Do While .Find.Found
    .Start = .Start - 1
    .MoveStartWhile " ", -1
    .Start = .Start - 1
    If .Characters.First Like "[?!:;.]" Then
      .End = .End + 1
      .InsertAfter .Characters.First
      With .Duplicate
        .Collapse wdCollapseStart
        .MoveEndWhile " ", 1
        .Delete
      End With
    End If
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
End Sub

Sub MoveMendeleyCitations()
  Dim aCC As ContentControl, aRng As Range
  For Each aCC In ActiveDocument.ContentControls
    If aCC.Tag Like "MENDELEY_CITATION*" Then
      Set aRng = aCC.Range
      aRng.Start = aRng.Start - 2
      aRng.End = aRng.End + 1
      Do While aRng.Characters.First = " "
        aRng.Start = aRng.Start - 1
      Loop
      aRng.Select
      If aRng.Characters.First Like "[?!:;.]" Then
        aRng.InsertAfter aRng.Characters.First
        aRng.Characters.First.Delete
        If aRng.Characters.First <> " " Then aRng.InsertBefore " "
      End If
    End If
  Next aCC
End Sub