Opening excel from word

[AXbean]

Hello experts! I have a macro in Word that is supposed to open Excel and paste a previous selection from Word into a new spreadsheet. It all works very well, except when Excel starts up programmatically, two windows open and the selection is pasted in both windows. How do I get it to only open one window?
Here is the code from Word:

Sub ExportwordtoexcelNew()
    Dim wordDoc As Object
    Dim oXL As Excel.Application
    Dim DocTarget As Word.Document
    Dim Target As Excel.Workbook
    Dim tSheet As Excel.Worksheet
    Dim ExcelWasNotRunning As Boolean
    

Dim YesOrNoAnswerToMessageBox As String
Dim QuestionToMessageBox As String
    QuestionToMessageBox = "Do you want Excel to open and paste your selection?"
    YesOrNoAnswerToMessageBox = MsgBox(QuestionToMessageBox, vbYesNo, "QuikBots for Word")
    If YesOrNoAnswerToMessageBox = vbYes Then
    
Set wordDoc = GetObject(, "word.application")
wordDoc.Selection.WholeStory
Selection.Copy


'If Excel is running, get a handle on it; otherwise start a new instance of Excel
On Error Resume Next
Set oXL = GetObject(, "Excel.Application")



'Install Add-ins
If Err Then
     ExcelWasNotRunning = True
     Set oXL = New Excel.Application
   
    For Each oAddIn In oXL.AddIns
        With oAddIn
            If .Installed Then
                .Installed = False
                .Installed = True
            End If
        End With
    Next oAddIn
End If

oXL.Visible = True
'oXL.ActiveWindow.Close SaveChanges:=False

Set Target = oXL.Workbooks.Add
Set tSheet = Target.Sheets(1)
tSheet.Paste

'Minimize word so you can see Excel
'wordDoc.Application.WindowState = wdWindowStateMinimize


    Else
    End If
Set oXL = Nothing
End Sub

[gmayor]

Try the following, however Word nd Excel formats are different from one another so I am not sure of the point of the exercise.

Sub ExportWordtoExcelNew()
Dim wordDoc As Document
Dim oXL As Object
Dim Target As Object
Dim tSheet As Object
Dim YesOrNoAnswerToMessageBox As String
Dim QuestionToMessageBox As String


    QuestionToMessageBox = "Do you want Excel to open and paste your selection?"
    YesOrNoAnswerToMessageBox = MsgBox(QuestionToMessageBox, vbYesNo, "QuikBots for Word")
    If YesOrNoAnswerToMessageBox = vbYes Then
        Set wordDoc = ActiveDocument
        wordDoc.Range.Copy

        'If Excel is running, get a handle on it; otherwise start a new instance of Excel
        On Error Resume Next
        Set oXL = GetObject(, "Excel.Application")
        If Err Then
            Set oXL = CreateObject("Excel.Application")
        End If
        On Error GoTo 0

        oXL.Visible = True
        'oXL.ActiveWindow.Close SaveChanges:=False

        Set Target = oXL.Workbooks.Add
        Set tSheet = Target.Sheets(1)
        tSheet.Paste

        'Minimize word so you can see Excel
        'wordDoc.Application.WindowState = wdWindowStateMinimize
    End If
    Set wordDoc = Nothing
    Set oXL = Nothing
    Set Target = Nothing
    Set tSheet = Nothing
End Sub

[Pecoflyer]

Hi, Please,do not crosspost your question on multiple forums without including links here to the other threads on other forums.

Cross-posting is when you post the same question in other forums on the web. The last thing you want to do is waste people's time working on an issue you have already resolved elsewhere. We prefer that you not cross-post at all, but if you do (and it's unlikely to go unnoticed), you MUST provide a link (copy the url from the address bar in your browser) to the cross-post.

We are here to help so help us to help you!

Read this to understand why we ask you to do this, and then please edit your first post to include links to any and all cross-posts in any other forums (not just this site)

http://www.excelguru.ca/forums/showt...xcel-from-word