Trying to change Regular to Superscript and vice versa

wardw · #1 07-01-2016, 11:26 AM

I'm trying to build a macro that changes regular selected text to superscript and superscript text to regular. I'm using

Code:

If Selection.Font.Superscript = True Then
        With Selection.Font
            .Superscript = False
        End With
    ElseIf Selection.Font.Regular = True Then
        With Selection.Font
            .Superscript = True
        End With
    End If

But compiling this gets "Method or data member not found", with Regular highlighted. There's no objection to Selection.Font.Superscript or .Subscript or many other designations, but I can't find out what the designation is for just regular, normal, unformatted text. Selection.Font.Normal triggers the error as well.

I tried to just record a macro by selecting a superscript and changing it to regular, but this is how "regular" was described . . .

Code:

With Selection.Font
        .Name = "Times New Roman"
        .Size = 10
        .Bold = False
        .Italic = False
        .Underline = wdUnderlineNone
        .UnderlineColor = wdColorAutomatic
        .StrikeThrough = False
        .DoubleStrikeThrough = False
        .Outline = False
        .Emboss = False
        .Shadow = False
        .Hidden = False
        .SmallCaps = False
        .AllCaps = False
        .Color = wdColorAutomatic
        .Engrave = False
        .Superscript = False
        .Subscript = False
        .Spacing = -0.15
        .Scaling = 100
        .Position = 0
        .Kerning = 0
        .Animation = wdAnimationNone
    End With

. . . and I'm not sure how to integrate that into my code. Do I need to specify all those parameters, or is there a simpler way to say "not superscript or subscript"?

jpl · #2 07-01-2016, 11:57 AM

Peut être une solution :

Code:

Sub essai()
    Dim c As Range
    For Each c In Selection.Characters
        With c.Font
            If .Superscript = True Then
                .Superscript = False
            ElseIf .Superscript = False And .Subscript = False Then
                .Superscript = True
            End If
        End With
    Next c
End Sub

jpl · #3 07-01-2016, 12:13 PM

There is a clumsiness in my code: we can delete(eliminate) the condition .Superscript = false

wardw · #4 07-01-2016, 04:40 PM

Thanks so much, JPL; this worked fine for my purposes.

macropod · #5 07-05-2016, 06:56 PM

To switch between regular & superscript, all you need is:

Code:

Sub Demo()
With Selection.Font
  .Superscript = Not .Superscript
End With
End Sub

jpl · #6 07-07-2016, 01:14 AM

Bonjour à vous.

If the selection contains a mixture of regular, superscript and subscript, "Demo" changes selected text to superscript.
"essai" changes regular to superscript, superscript to regular and respects subscript.
On the other hand, "Demo" works on multiple selections, but not "essai". The problem results from the "Characters" collection.

Si la sélection contient un mélange de caractères normaux, d'indices et d'exposants, la macro "Demo" transforme tout en exposant.
La macro "essai" transforme les caractères normaux en exposants, les exposants en caractères normaux et respecte les indices.
Par contre, la macro "Demo" fonctionne sur les sélections multiples, mais pas la macro "essai". Le problème provient de la collection "Characters".

macropod · #7 07-07-2016, 11:58 AM

Hardly relevant, since the OP never specified subscript as a consideration for the format change...

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Sub/superscript hotkey danish keyboard	Fakecake	OneNote	1	04-05-2015 04:39 AM
excel update superscript by 1	htownpaper	Word	8	12-08-2014 06:38 PM
Insert superscript into a textbox	Deltaj	Word VBA	3	11-30-2014 04:23 PM
Regular (roman) character style doesn't change text to roman	kcbenson	Word	2	10-16-2014 01:31 PM
Sizing cells to pics (or even vice versa?)	Guloluseus	Excel	1	07-27-2014 11:24 AM