Adding to a macro

Ulodesk · #1 03-03-2016, 08:24 AM

Allen Wyatt posted this useful macro on WordTips.net quite a while ago. I would like an addition to it that will, after pasting, strip all styles from the tables, including table styles. I would normally use Ctrl+spacebar, Ctrl+Q, and Alt+Ctrl+u.
This would be useful for anyone needing to bring the tables from another document into one in, for instance, a custom template with its own table styles.

I'm sure this is a simple matter for someone who knows VBA, and I thank him or her in advance.

Code:

Sub CopyTables()
    Dim Source As Document
    Dim Target As Document
    Dim tbl As Table
    Dim tr As Range

    Set Source = ActiveDocument
    Set Target = Documents.Add

    For Each tbl In Source.Tables
        Set tr = Target.Range
        tr.Collapse wdCollapseEnd
        tr.FormattedText = tbl.Range.FormattedText
        tr.Collapse wdCollapseEnd
        tr.Text = vbCrLf
    Next
End Sub

macropod · #2 03-06-2016, 04:37 PM

Try:

Code:

Sub CopyTables()
Application.ScreenUpdating = False
Dim DocSrc As Document, DocTgt As Document, Tbl As Table, Rng As Range
Set DocSrc = ActiveDocument: Set DocTgt = Documents.Add
For Each Tbl In DocSrc.Tables
  Set Rng = DocTgt.Characters.Last
  With Rng
    .Collapse wdCollapseEnd
    .FormattedText = Tbl.Range.FormattedText
    .Tables(1).Style = "Table Grid"
    .Collapse wdCollapseEnd
    .InsertAfter vbCr
  End With
Next
Set DocSrc = Nothing: Set DocTgt = Nothing
Application.ScreenUpdating = True
End Sub

Ulodesk · #3 03-07-2016, 07:43 AM

Paul, thank you, as always. I can certainly use this when maintaining the paragraph styles in the original table will be the best procedure. I would like, however, to be able to strip the paragraph and character styles as well, as I tried to indicate in my post, so that I have a "style-less" (I know Normal will be applied) table and text.
My reason is, that in my proposal work, I occasionally have a long document with lots of tables and a style list from, shall we say, the subterranean, to import, clean, into a custom template. Making short work of the table reformatting will be a very significant time-saver in such cases.

Much obliged, and best wishes.
Philip

macropod · #4 03-07-2016, 01:31 PM

Quote:

Originally Posted by Ulodesk

I would like, however, to be able to strip the paragraph and character styles as well

In that case, simply insert:
.Style = wdStyleNormal
.Font.Reset
after:
.FormattedText = Tbl.Range.FormattedText

Ulodesk · #5 03-07-2016, 01:40 PM

Splendid! Thanks again.

P

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Adding a save as macro button to a template	nparsons75	Word	6	01-08-2016 07:47 AM
VBA Code for adding Macro to QAT	OTPM	Project	4	08-22-2013 01:33 PM
Adding macro to normal.dotm programmatically	etippelt	Word VBA	6	04-08-2013 05:55 PM
Adding Macro menu to the right click menu (Word 2007)	masam123	Word	0	10-14-2011 04:05 AM
Macro for automatically adding filename without .doc	RPM7	Word VBA	0	04-29-2010 01:43 AM