Sub Demo()
Application.ScreenUpdating = False
Dim Tbl As Table, Rng As Range, strTxt As String, i As Long, j As Long
Options.DefaultHighlightColorIndex = wdYellow
With ActiveDocument
  For Each Tbl In .Tables
    With Tbl
      For i = 1 To .Rows.Count
        Set Rng = .Cell(i, 2).Range
        With .Cell(i, 1).Range
          For j = 1 To .Words.Count
            strTxt = Trim(.Words(j))
            With Rng.Find
              .ClearFormatting
              .Text = strTxt
              With .Replacement
                .ClearFormatting
                .Highlight = True
                .Text = "^&"
              End With
              .Format = True
              .Forward = True
              .MatchCase = False
              .MatchWholeWord = True
              .MatchWildcards = False
              .Wrap = wdFindStop
              .Execute Replace:=wdReplaceAll
            End With
          Next
        End With
      Next
    End With
  Next
End With
Application.ScreenUpdating = True
End Sub