Macro not running on exiting legacy drop down menu.

[supremegrandruler]

I have a simple drop down menu and right-cliked it -> Exit and selected my macro (posted below). But when I select an item from the menu, nothing happens.

Public Sub Test1()
    With ActiveDocument.Content.Find
        .Text = "BOLD"
        .MatchWildcards = True
        .MatchCase = True
        .Replacement.Font.Bold = True
        .Execute Replace:=wdReplaceAll
    End With
End Sub

[macropod]

There is nothing wrong with the macro, as such. Without knowing how you're using your dropdown menu, though, it's impossible to say what the issue is. If you're referring to a dropdown formfield, the only macro one of those can run is the one specified in it's properties as the 'exit' macro. your macro security settings would also have to allow macros to run.

[supremegrandruler]

I can run the macro just fine by clicking "Macros -> Run MyMacro".

I'm using a legacy drop down field. I right clicked it and selected MyMacro in the "Exit" field. I protect the document to "Filling in forms" so I can start using the drop down. Then I select a value from the drop down menu but nothing happens.

[gmayor]

In order for the macro to be able to do anything in a protected form, you are going to have to include code to unprotect (and reprotect) the form. In your example:

Public Sub Test1()
Dim bProtected As Boolean
    'Unprotect the file
    If ActiveDocument.ProtectionType <> wdNoProtection Then
        bProtected = True
        ActiveDocument.Unprotect Password:=""
    End If
    With ActiveDocument.Content.Find
        .Text = "BOLD"
        .MatchWildcards = True
        .MatchCase = True
        .Replacement.Font.Bold = True
        .Execute Replace:=wdReplaceAll
    End With
    If bProtected = True Then
        ActiveDocument.Protect _
                Type:=wdAllowOnlyFormFields, _
                NoReset:=True, _
                Password:=""
    End If
End Sub

and note that your macro was called Test1 and not MyMacro ! Run Test1 on exit from the field. On Exit means when you leave the field, not when you select an item.

[supremegrandruler]

Thanks. It works save for one thing: it only bolds "BOLD" when it's not located in a drop down menu. I want it to bold also the word "BOLD" even in drop down menus.

[gmayor]

You cannot embolden only the word BOLD in a dropdown form field, unless you convert the field result to plain text (whereupon it will no longer be a form field). You can however embolden the whole field range if the dropdown result contains the world BOLD e.g.

Public Sub Test1()
Dim bProtected As Boolean
Dim oFld As FormField
    If ActiveDocument.ProtectionType <> wdNoProtection Then
        bProtected = True
        ActiveDocument.Unprotect Password:=""
    End If
    With ActiveDocument.Content.Find
        .Text = "BOLD"
        .MatchWildcards = True
        .MatchCase = True
        .Replacement.Font.Bold = True
        .Execute Replace:=wdReplaceAll
    End With
    For Each oFld In ActiveDocument.FormFields
        If InStr(1, oFld.Result, "BOLD") > 0 Then
            oFld.Range.Font.Bold = True
        Else
            oFld.Range.Font.Bold = False
        End If
    Next oFld
    If bProtected = True Then
        ActiveDocument.Protect _
                Type:=wdAllowOnlyFormFields, _
                NoReset:=True, _
                Password:=""
    End If
End Sub