VBA Dropdown change list Entries automatically

QA_Compliance_Advisor · #1 09-12-2014, 06:17 AM

Quote:

Originally Posted by gmayor

You will need the add-in which handles the folders and sub folders - http://www.gmayor.com/document_batch_processes.htm
which I referred to in my first post. Run the above code as a custom process.

The instructions are on the web page.

gmayor, thank you clearly being dense.

macropod · #2 09-16-2014, 03:23 AM

Try:

Code:

Function Ddown(oDoc As Document) As Boolean
Dim oFF As FormField, i As Long, bChng As Boolean
    On Error GoTo Err_Handler
    For Each oFF In oDoc.FormFields
        With oFF
            If .Type = wdFieldFormDropDown Then
                bChng = False
                If .Name = "Dropdown1" Then
                    bChng = True
                Else
                    For i = 1 To .DropDown.ListEntries.Count
                        If .DropDown.ListEntries(i).Name = "Select Vessel" Then
                            bChng = True
                            Exit For
                        End If
                    Next
                End If
            End If
            If bChng = True Then
                .Name = "drpVessel"
                'With .Dropdown.ListEntries
                '    .Clear
                '    .Add "Item 1"
                '    .Add "Item 2"
                '    .Add "Item 3"
                '    .Add "Item 4"
                'End With
                Exit For
            End If
        End With
    Next oFF
    Ddown = True
lbl_Exit:
    Exit Function
Err_Handler:
    Ddown = False
    Resume lbl_Exit
End Function

QA_Compliance_Advisor · #3 09-16-2014, 04:36 AM

amasing!

Could you explain how I could call this function from within the macro https://www.msofficeforums.com/word-...er-footer.html

not too strong in understanding how I can call a subroutine or function.

gmayor · #4 09-16-2014, 04:49 AM

Quote:

Originally Posted by QA_Compliance_Advisor

amasing!

Could you explain how I could call this function from within the macro https://www.msofficeforums.com/word-...er-footer.html

not too strong in understanding how I can call a subroutine or function.

I had missed Paul's reply when I replied also

However to call a function you call it by name and apply the named parameter e.g

Ddown ActiveDocument.

It was however intended to be used with my batch processor linked earlier in the thread which provides the folder and sub folder handling

QA_Compliance_Advisor · #5 09-16-2014, 06:12 AM

Graham, yes it works well with your batch processor - however, since i have so many different things to do i knida want it it all done in a one click rather than processing 2000 documents six times.

so I want to use your batch processing but have all the other function called one at a time during the batch processing.

gmayor · #6 09-16-2014, 07:29 AM

Do you mean you want to add the following?

Code:

With wdDoc
    'Process the body
    Call Update(.Range)
    'Process textboxes etc in the body
    For Each Shp In .Shapes
        With Shp.TextFrame
            If .HasText Then
                Call Update(.TextRange)
            End If
        End With
    Next
    For Each Sctn In .Sections
        For Each HdFt In Sctn.Headers
            With HdFt
                If .LinkToPrevious = False Then
                    'Process the header
                    Call Update(.Range)
                End If
            End With
        Next
    Next
    .Close SaveChanges:=True
End With

In that case bear in mind that the document used by the code I posted is oDoc rather than wdDoc and you must no close that document from the code as the add-in takes care of that, so it is simply a matter of inserting the relevant bits of the code into the original macro

So you need to add this bit after the line
Next oFF
Don't forget to include The Update code and to declare the additional variables used here at the top of the function. I haven't tested you additional code.

Code:

With oDoc
    'Process the body
    Call Update(.Range)
    'Process textboxes etc in the body
    For Each Shp In .Shapes
        With Shp.TextFrame
            If .HasText Then
                Call Update(.TextRange)
            End If
        End With
    Next
    For Each Sctn In .Sections
        For Each HdFt In Sctn.Headers
            With HdFt
                If .LinkToPrevious = False Then
                    'Process the header
                    Call Update(.Range)
                End If
            End With
        Next
    Next
End With

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Multiple entries in dropdown lists	paul_pearson	Word VBA	154	11-08-2025 03:51 PM
Duplicating entries on multiple tabs automatically	jbexley	Excel	0	08-28-2014 04:48 PM
Captions automatically updating all previous entries	jhats	Word	1	07-29-2014 11:53 PM
Dropdown list, Macro	shield5	Excel Programming	7	10-27-2013 01:51 AM
Change cell color everytime a value is selected in dropdown list	angelica_gloria	Excel	4	01-27-2012 06:47 PM