Macro to find text only footnote numbers

macropod · #8 04-10-2014, 07:05 PM

If you only want to find numbers that increment try:

Code:

Sub Demo()
Dim Rslt, Rng As Range, i As Long
Set Rng = Selection.Range
With ActiveDocument.Range
  With .Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "[0-9]{1,}"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = False
    .MatchWildcards = True
    .Execute
  End With
  Do While .Find.Found
    If .Text = i + 1 Then
      .Select
      Rslt = MsgBox("Replace this instance of:" & vbCr & .Text, vbYesNoCancel)
      If Rslt = vbCancel Then Exit Sub
      If Rslt = vbYes Then
        .Text = vbNullString
        i = i + 1
      End If
    ElseIf .Text = i Then
      .Select
      Rslt = MsgBox("Replace this instance of:" & vbCr & .Text, vbYesNoCancel)
      If Rslt = vbCancel Then Exit Sub
      If Rslt = vbYes Then .Text = vbNullString
    End If
    .Collapse wdCollapseEnd
    .Find.Execute
  Loop
End With
Rng.Select
End Sub

Note: As coded, the macro includes an ElseIf test to pick up repeats of the last number. You can delete that if you don't want it.

I'm not sure what you mean by "Is there a way I could use a regular expression to do the search that would exclude numerals to the left or right of my target?" The code in both this post and my previous one (both of which use wildcards, which are Word's equivalent of regular expressions) only picks up whole numbers anyway - it won't find just the 1 or 11 within 110 or 211 or 123114, for example.

PS: When posting code, please use the code tags. They're on the 'Go Advanced' tab at the bottom of this screen.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Macro to find text and replace with form field containing that text	iiiiifffff	Word VBA	16	06-04-2016 01:47 AM
Macro to find text in between two characters and then format selected text?	qcom	Word	5	02-19-2015 11:23 PM
VBA code for Microsoft Word macro — select text and insert footnote	ndnd	Word VBA	10	01-06-2015 01:47 PM
Need help on Macro 03- Find text - if text is blank then remove line	simpleonline1234	Word VBA	1	02-25-2011 02:28 AM
Find and replace page numbers in body of text	tollanarama	Word	3	02-13-2011 06:00 AM