replace letters by font without losing format

macropod · #1 02-14-2014, 04:59 PM

You could use code like the following, but, if you're updating whole paragraphs, you really should do so by changing the paragraph Style; even for individual characters, if they're not in the same font as the paragraph Style, you should redefine them using a character Style.

Code:

Sub UpdateDocuments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.doc", vbNormal)
While strFile <> ""







  Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  With wdDoc.Range.Find
    .ClearFormatting
    .Text = "[A-Za-z0-9]"
    .Font.Name = "Times New Roman"
    With .Replacement
      .ClearFormatting
      .Text = "^&"
      .Font.Name = "Tahoma"
    End With
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchWildcards = True
    .Execute Replace:=wdReplaceAll
  End With
  wdDoc.Close SaveChanges:=True
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

The above code will change all letters and numbers in all documents in the selected folder from Times New Roman to Tahoma. Since you haven't indicated anything substantial about what characters you're replacing, I can't provide much more help than that for the Find string.

PS: Don't store the file containing the macro in the same folder as the files to be processed.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Macro to replace digits with letters	Bananabean	Word VBA	6	09-14-2013 09:28 PM
How to replace all font occurencies by another (e.g. Arial-->Courier)	pstein	Word	1	04-30-2013 05:58 AM
Find and Replace maintain format	winningson	Word	3	01-19-2013 05:38 AM
Format Font	herbhh	Word	10	05-23-2011 08:29 AM
How do I import text columns with specified spacing between words w/o losing format?	Fucius	Word	0	08-09-2010 06:23 PM