Open header to insert text into bookmark

[Amapola188]

Good Morning, my code breaks at line 3 (excluding comments) of below code. It says it can't find the bookmark. I have checked that the bookmark is there and spelling etc is all correct. - I suspect that it may not open the header and therefore don't find the bookmark in the main document?

Anybody any idea why this would be.

      
        'Open Header
         Selection.GoTo What:=wdGoToPage, Which:=wdGoToNext, Name:="2"
         ActiveDocument.ActiveWindow.ActivePane.View.SeekView = wdSeekCurrentPageHeader
        
        'Insert Data into Header
         Selection.GoTo What:=wdGoToBookmark, Name:="BMQuoteNumberHeader"
         Selection.TypeText Text:=txtQuoteNumber.Text
        
        'Close Header
         ActiveDocument.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument

Thank you!

Christine
Auckland, NZ

[macropod]

Hi Christine,

Try:
Call UpdateBookmark("BMQuoteNumberHeader", txtQuoteNumber.Text)
with:

Sub UpdateBookmark(BmkNm As String, NewTxt As String)
Dim BmkRng As Range
With ActiveDocument
  If .Bookmarks.Exists(BmkNm) Then
    Set BmkRng = .Bookmarks(BmkNm).Range
    BmkRng.Text = NewTxt
    .Bookmarks.Add BmkNm, BmkRng
  End If
End With
Set BmkRng = Nothing
End Sub

Note: There is no need for the GoTo, to explicitly access the header, or to select anything. Furthermore, unlike your code, if you change your mind about what should appear in the header, the content gets changed - your's just appends the new content.

[Amapola188]

Thanks, Paul.
Code now running perfectly! - Have a good day, can't be bare sunrise yet!
Christine

[macropod]

Nah, sun 'd been up 3/4hr already.