How to insert paragraph character after every 500 characters?

macropod · #2 06-30-2012, 01:15 AM

Quote:

Those sentences should not contain more than 500 characters.

Even that makes for incredibly long sentences!

Powerpoint slides should have the least number of words possible to convey the main points of what is being discussed, not reams of text for people to read.

Be that as it may, try:

Code:

Sub TextSplitter()
Dim Rng As Range
Application.ScreenUpdating = False
With ActiveDocument
  Set Rng = .Range(0, 0)
  Do
    With Rng
      On Error GoTo ErrExit
      .MoveEndUntil cset:=vbCr, Count:=wdForward
      If Len(.Text) > 500 Then
        .End = .Start + 500
        .End = .Start + InStrRev(Rng.Text, ".") + 1
        If .Characters.Last.Text <> vbCr Then
          .Characters.Last.Delete
          .InsertAfter vbCr
        End If
      End If
      DoEvents
      .Start = .Paragraphs.Last.Next.Range.Start
    End With
  Loop Until Rng Is Nothing
ErrExit:
End With
Set Rng = Nothing
Application.ScreenUpdating = True
End Sub

The above macro looks forward in paragraph blocks. If the paragraph has more than 500 characters, it stops at the 500th character then looks backwards for the last preceding period, following which it ensures the presence of a paragraph break.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Restricting paragraph styles without restricting character styles	Red Pill	Word	5	05-25-2012 01:06 PM
character set	bobster	Word	0	06-07-2011 10:17 AM
tab key arrows first character	carolinason	Word	6	10-30-2010 06:45 PM
Junk characters (box-like characters) in Word file	Sashikala	Word	1	04-20-2010 02:03 PM
Character style stripped while applying paragraph style	sams_gates	Word	0	08-29-2009 02:03 AM