hi



im looking for a macro that simply reflect specific objects among all slides. for example if i place a logo on top of a slide'[s picture i want this logo to be reflected on all slides.

thanks
Shay

Assuming the logo is selected

Sub paster()
Dim osld As Slide
If ActiveWindow.Selection.Type = ppSelectionShapes Then
ActiveWindow.Selection.ShapeRange.Cut
For Each osld In ActivePresentation.Slides
osld.Shapes.Paste
Next osld
End If
End Sub

__________________
Microsoft PowerPoint MVP 2007-2023
Free Advanced PowerPoint Tips and Tutorials

that's great! lets say i used your script over 200 slides and next week my boss will tell me to change to position of the logo...what should i do than ? how can i say "update position in all slide? (hope im not rude

You could kill the boss!

Alternatively you could modify the original script (you will have to start over)

Sub paster()
Dim osld As Slide
If ActiveWindow.Selection.Type = ppSelectionShapes Then
ActiveWindow.Selection.ShapeRange.Cut
For Each osld In ActivePresentation.Slides
With osld.Shapes.Paste
.Tags.Add "LOGO", "YES"
End With
Next osld
End If
End Sub

This does the same thing but adds an invisible tag called "LOGO" to the pasted shapes.

When your boss changes his mind - move one logo to the new position and select it then run this second script


Sub reposition()
Dim osld As Slide
Dim oshp As Shape
Dim sngL As Single
Dim sngT As Single
If ActiveWindow.Selection.Type = ppSelectionShapes Then
With ActiveWindow.Selection.ShapeRange(1)
sngL = .Left
sngT = .Top
End With
For Each osld In ActivePresentation.Slides
For Each oshp In osld.Shapes
If oshp.Tags("LOGO") = "YES" Then
oshp.Left = sngL
oshp.Top = sngT
Exit For
End If
Next oshp
Next osld
End If
End Sub

__________________
Microsoft PowerPoint MVP 2007-2023
Free Advanced PowerPoint Tips and Tutorials