Contacts

[Wikus Botha]

Hi


I have send emails out to my adress book using my groups instead of sending it individually. There are people that want to unsubscribe. How do I find in which group the specific contact is without searching each group manually?
I have like 30 groups with about 80 adress in each. You can imagine how long that is going to take manually.

Please respond
Thank you
Wikus

[gmayor]

The following macro will list the groups a named member appears in:

Sub ListDistributionGroupNamesContainingMember()
Dim olNameSpace As Outlook.NameSpace
Dim olFolder As Outlook.Folder
Dim olDistList As Outlook.DistListItem
Dim olFolderItems As Outlook.Items
Dim olListMember As String
Dim sList As String
Dim x As Integer
Dim y As Integer
Dim iCount As Integer

    olListMember = LCase(InputBox("Enter name of list member to be found", _
                                  "Find name in Distribution Lists"))
    Set olNameSpace = GetNamespace("MAPI")
    Set olFolder = olNameSpace.GetDefaultFolder(olFolderContacts)
    Set olFolderItems = olFolder.Items
    iCount = olFolderItems.Count
    sList = ""
    For x = 1 To iCount
        If TypeName(olFolderItems.Item(x)) = "DistListItem" Then
            Set olDistList = olFolderItems.Item(x)
            For y = 1 To olDistList.MemberCount
                If InStr(1, olDistList.GetMember(y).Name, olListMember) Then
                    If sList = "" Then
                        sList = sList & olDistList.GetMember(y).Name _
                                & Chr(32) & ChrW(8212) & Chr(32) & olDistList.DLName
                    Else
                        sList = sList & vbCr & olDistList.GetMember(y).Name _
                                & Chr(32) & ChrW(8212) & Chr(32) & olDistList.DLName
                    End If
                End If
            Next y
        End If
    Next x
    MsgBox sList
lbl_Exit:
    Exit Sub
End Sub