Sub GetFileStats()
Application.ScreenUpdating = False
Dim FSO As Object, oItem As Object, StrDtTm As String
Dim strPath As String, strFile As String, strFullName As String, strData As String
strPath = GetFolder
If strPath = "" Then Exit Sub
strPath = strPath & "\"
strData = "File Stats For" & vbTab & strPath
If FSO Is Nothing Then Set FSO = CreateObject("Scripting.FileSystemObject")
strFile = Dir(strPath & "*.xls", vbNormal)
While strFile <> ""
  strFullName = strPath & strFile
  Set oItem = FSO.GetFile(strFullName)
  strData = strData & vbCrLf & vbCrLf & "Filename:" & vbTab & strFile & vbCrLf & _
    "Date Created: " & vbTab & Format(oItem.DateCreated, "DD/MMM/YYYY @ hh:mm:ss") & vbCrLf & _
    "Date Last Modified: " & vbTab & Format(oItem.DateLastModified, "DD/MMM/YYYY @ hh:mm:ss")
  strFile = Dir()
Wend
Open strPath & "FileStats.txt" For Output As #1
Print #1, strData
Close #1
Application.ScreenUpdating = True
End Sub
Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function