Private Sub Insert_Checkboxes()
     Dim myCell As Range
     Dim myRng As Range
     Dim CBX As CheckBox

     With ActiveSheet
         'delete existing checkboxes from sheet, links are not cleared.
         .CheckBoxes.Delete
         'Exit Sub   '<~~~~~ uncomment to delete checkboxes only. Linked cells are NOT cleared.
         Set myRng = .Range("A2:A11")    '<~~~~~ enter the range to have checkboxes
     End With

Application.ScreenUpdating = False
     For Each myCell In myRng.Cells
         With myCell
             Set CBX = .Parent.CheckBoxes.Add _
                         (Top:=.Top, _
                          Left:=.Left, _
                          Width:=.Width, _
                          Height:=.Height)    'click area same size as cell
             CBX.Name = "CBX_" & .Address(0, 0)
             CBX.Caption = "Label goes here"     'or whatever you want
             CBX.Value = xlOff    'initial value unchecked
             CBX.LinkedCell = .Offset(0, 1).Address     '<~~~~~ enter offset to linked cell
         End With
     Next myCell
Application.ScreenUpdating = True
End Sub