How to combine many paragraphs in one paragraph?

Jamal NUMAN · #1 07-04-2011, 02:12 AM

How to combine many paragraphs in one paragraph?

please, see the attached images that show my question

In case we need to quote from other's work then in this case we need to copy and paste the whole lines as they are. once they are pasted in word, then each line appears as one paragraph (particularly if they are pasted from pdf file).

How to make these paragraphs in one paragraph AUTOMATICALLY?

regards

Jamal

macropod · #2 07-04-2011, 02:59 AM

Hi Jamal,

If you're pasting content with paragraph breaks in it (eg from PDFs & emails), Word can't join them automatically. However, it can be done fairly easily.

Whenever paste text from a PDF, web site or an email, you may end up with a paragraph break at the end of every line within a logical paragraph, and two such breaks between logical paragraphs. You can fix this using a series of wildcard Find/Replace actions, using a macro like:

Code:

Sub CleanUpPastedText()
'Turn Off Screen Updating
Application.ScreenUpdating = False
With ActiveDocument.Range.Find
  .ClearFormatting
  .Replacement.ClearFormatting
  .Forward = True
  .Wrap = wdFindStop
  .Format = False
  .MatchAllWordForms = False
  .MatchSoundsLike = False
  .MatchWildcards = True
  'Eliminate spaces & tabs before paragraph breaks.
  .Text = "[ ^s^t]{1,}^13"
  .Replacement.Text = "^p"
  .Execute Replace:=wdReplaceAll
  'Replace single paragraph breaks with a space
  .Text = "([!^13])([^13])([!^13])"
  .Replacement.Text = "\1 \3"
  'Replace all double spaces with single spaces
  .Execute Replace:=wdReplaceAll
  .Text = "[ ]{2,}"
  .Replacement.Text = " "
  'Delete hypens in hyphenated text formerly split across lines
  .Execute Replace:=wdReplaceAll
  .Text = "([a-z])-[ ]{1,}([a-z])"
  .Replacement.Text = "\1\2"
  .Execute Replace:=wdReplaceAll
  'Limit paragraph breaks to one per 'real' paragraph.
  .Text = "[^13]{1,}"
  .Replacement.Text = "^p"
  .Execute Replace:=wdReplaceAll
End With
'Restore Screen Updating
Application.ScreenUpdating = True
End Sub

Note that the code assumes there are at least two such paragraph breaks between the 'real' paragraphs.

For PC macro installation & usage instructions, see: http://www.gmayor.com/installing_macro.htm
For Mac macro installation & usage instructions, see: http://word.mvps.org/Mac/InstallMacro.html

If you'd prefer to run the macro against just a selected range, change:
ActiveDocument
to:
Selection

Jamal NUMAN · #3 07-04-2011, 05:03 AM

thank you Paul. You have a solution for each single challenge.

But how to make the macro works only on the selected but not in the whole document?

regards

Jamal

macropod · #4 07-04-2011, 07:38 PM

Hi Jamal,

As advised in my previous reply, change:
ActiveDocument.Content.Find
to
Selection.Find

- and have something selected

Jamal NUMAN · #5 07-05-2011, 02:37 AM

Thanx Paul. Perfect. It did work

regards

Jamal

Jamal NUMAN · #6 07-09-2011, 04:40 PM

Hi Paul,

How to develop the above macro to include combining also the paragraphs separated by (shift + Enter) or tabs as well as deleting all spaces and punctuation marks?

thank you

regards

Jamal

macropod · #7 07-11-2011, 05:06 AM

Hi Jamal,

Shift-Enter creates a manual line break within a paragraph - it does not create a new paragraph. You can delete manual line breaks and tabs by inserting the follwing three lines:

Code:

  .Text = "[^t^l]{1,}"
  .Replacement.Text = " "
  .Execute Replace:=wdReplaceAll

before the line:
.Text = "[ ]{2,}"

Do you really want to delete all spaces and punctuation marks? That would give you text like:
Doyoureallywanttodeleteallspacesandpunctuationmark sThatwouldgiveyoutextlike

Jamal NUMAN · #8 07-11-2011, 05:47 AM

Quote:

Originally Posted by macropod

Hi Jamal,

Shift-Enter creates a manual line break within a paragraph - it does not create a new paragraph. You can delete manual line breaks and tabs by inserting the follwing three lines:

Code:

  .Text = "[^t^l]{1,}"
  .Replacement.Text = " "
  .Execute Replace:=wdReplaceAll

before the line:
.Text = "([ ])[ ]{1,}"

Do you really want to delete all spaces and punctuation marks? That would give you text like:
Doyoureallywanttodeleteallspacesandpunctuationmark sThatwouldgiveyoutextlike

thank you Paul.

You are right. i don't need to delete the spaces! i meant that i needed to delete all other marks except the spaces!

the reason i need this is that:

i save the pdf articles that i read by giving them the title of the article and the name of the author. As you know, as i copy and paste them from pdf file to the Word document, i got them separated in many paragraphs.

Also Windows is very sensitive if we include certain punctuation marks in the name of the file!!!!

this is why i need to combine all paragraph in one paragraph and to get rid of all punctuation marks!!!

i was doing these steps manually before you provide me with the Macro that combines paragraph.

regards

Jamal

Jamal NUMAN · #9 07-12-2011, 02:49 AM

Thank you Paul.

the code now doesn't remove the punctuation marks!!!!

what might be the problem?

regards

Jamal

macropod · #10 07-12-2011, 03:14 AM

Hi Jamal,

The code I posted in this thread never did remove punctuation marks!

Jamal NUMAN · #11 07-12-2011, 03:24 AM

Quote:

Originally Posted by macropod

Hi Jamal,

The code I posted in this thread never did remove punctuation marks!

Thank you Paul. That's right.

could you please, if your time permits, what should i add to the code to remove the punctuation marks?

regards

Jamal

macropod · #12 07-12-2011, 06:34 AM

Hi Jamal,

I really don't recommend doing that - it will cause the macro to delete punctation marks in text you're trying to clean up when it's been copied from pdfs, emails, web pages, etc when the punctuation should remain. Still, if that's what you want to do, insert the lines:

Code:

  .Text = "[,.;:‘’'“”""/\!\*\?\\]"
  .Replacement.Text = ""
  .Execute Replace:=wdReplaceAll

after the line:
.MatchWildcards = True

Jamal NUMAN · #13 07-13-2011, 01:37 AM

Thank you Paul. it worked like a char. that's what I've been looking for.

regards

Jamal

Jamal NUMAN · #14 03-07-2013, 01:15 PM

Hi Paul,

Sorry to bother you again with similar issues.

You have generously provided codes (attached) that:

1. Eliminate particular marks from a selected paragraph
2. Capitalized selected words except prepositions

My intent now is to eliminate spaces and to capitalize all selected words at a time.

For example, the “National spatial plan of zone one” will look like:

NationalSpatialPlanOfZoneOne

Thank you

Best

Jamal

macropod · #15 03-07-2013, 02:40 PM

The only way you can do that with Find/Replace is to input both the Find and Replace strings you want. A wildcard Find/Replace cannot change the capitalisation of a random string.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Track chages combine: Stumped!	Ulodesk	Word	2	01-03-2011 11:43 AM
Combine two forms into one	lwisniewski	Word VBA	3	12-24-2010 03:45 PM
Combine pst files?	markg2	Outlook	2	04-26-2010 03:09 PM
How do you combine two contact folders?	waikoloavrm	Outlook	0	04-12-2010 02:31 PM
Bulletizing one paragraph affects all paragraphs	GoodWebby	Word	0	10-10-2009 12:09 PM