Word 2003 Auto-generate file links?

[chrisjj]

Is there an in-built way or more likely add-on to auto-generate links from text matching my pattern, to external files?

E.g. turn every **(Xnnnn)** into a link to **folder\file Xnnnn.txt** ?

[gmayor]

There is no function that will automate this, but you should be able to achieve it with a macro e.g.

Sub Macro1()
Dim oRng As Range
Dim sFind As String
Dim sAddr As String
Dim sPath As String
    sFind = "(Xnnnn)" 'the text to find
    sAddr = Mid(sFind, 2, Len(sFind) - 2) 'remove the brackets from the searched text
    sPath = "folder\file " & sAddr & ".txt" 'assemble the link path
    Set oRng = ActiveDocument.Range
    With oRng.Find
        Do While .Execute(sFind)
            oRng.Hyperlinks.Add oRng, sPath, , , sFind
            oRng.End = oRng.Hyperlinks(1).Range.End
            oRng.Collapse 0
        Loop
    End With
lbl_Exit:
    Set oRng = Nothing
    Exit Sub
End Sub

The code assumes that sPath is a genuine path accessible from the document.
Note that I have not tested it with Word 2003, but I am pretty sure all the code examples worked in that version.

[chrisjj]

That's great. Thanks very much

I've enhanced to wildcard match:

Sub Macro1()
Dim oRng As Range
Dim sFind As String
Dim sAddr As String
Dim sPath As String
    sFind = "\((X[0-9]{5})\)"
    Set oRng = ActiveDocument.Range
    With oRng.Find
        .MatchWildcards = True
        Do While .Execute(sFind)
            'sAddr = oRng.Text
            sAddr = "???"
            sPath = "folder\file " & sAddr & ".txt" 'assemble the link path
            Debug.Print sPath
            oRng.Hyperlinks.Add oRng, sPath, , , oRng.Text
            oRng.End = oRng.Hyperlinks(1).Range.End
            oRng.Collapse 0
        Loop
    End With
lbl_Exit:
    Set oRng = Nothing
    Exit Sub
End Sub

but cannot find how to set sAddr to the first captured expression e.g. X12345. Any idea?

Attached.

[gmayor]

sAddr is the found text, so change it back to sAddr = oRng.Text
then process that instead of sFind to remove the brackets e.g.

sAddr = oRng.Text
sAddr = Mid(sAddr, 2, Len(sAddr) - 2)

[chrisjj]

Thank but I want to set sAddr to the first captured expression e.g. X12345, so sAddr is under control of the regular expression pattern, rather than reply upon VBS string processing.