Formatting applied to one paragraph affects the entire document.

Charles Kenyon · #16 07-15-2025, 08:36 PM

I do not have a macro for that in my pocket. If you need it, someone here will likely write it. I put together something similar on this page.

Spelling Checker Does Not Work! - Proofing Language Keeps Changing - Solutions

The macro name is StyleEnglishAUSNormalTemplate() and it also changes the proofing language in the normal template.

macropod · #17 07-15-2025, 09:19 PM

You could, of course, save yourself a lot of bother and just use a Style other than Normal - as per my original suggestion.

Here's a simple macro to remove the 'automatic update' attribute from the Normal Style in both your document and its template, and to clear the 'update document styles' property in your document.

Code:

Sub StyleReset()
ActiveDocument.UpdateStylesOnOpen = False
ActiveDocument.Styles(wdStyleNormal).AutomaticallyUpdate = False
Documents.Open ActiveDocument.AttachedTemplate.FullName, , False
ActiveDocument.Styles(wdStyleNormal).AutomaticallyUpdate = False
ActiveDocument.Close True
End Sub

For PC macro installation & usage instructions, see: Installing Macros
For Mac macro installation & usage instructions, see: https://wordmvp.com/Mac/InstallMacro.html

As for your problem with using PrintScreen, that strongly suggests a faulty Windows installation. You should repair it.

Charles Kenyon · #18 07-16-2025, 06:33 AM

I prefer to have the TOC, Table of Figures and Table of Authorities styles Auto Update.
Here is the macro based on the one for proofing language.

Code:

Sub NormalStylesAutoUpdateOff()
    '   Written 16 July 2025
    '   Charles Kenyon
    '   Intended to set all styles in Normal template (except those used in TOC, TOF, or TOA) to not automatitically update
    '   Use right after opening Word
    '
    ' https://www.msofficeforums.com/word/...-document.html
    '
    Application.ScreenUpdating = False
    Application.NormalTemplate.OpenAsDocument
    Dim aStyle As Style
    On Error Resume Next    ' Some styles have no language attribute and will give an error
    For Each aStyle In ActiveDocument.Styles
        Select Case aStyle.NameLocal
            Case "TOC 1", "TOC 2", "TOC 3", "TOC 4", "TOC 5", "TOC 6", "TOC 7", "TOC 8", "TOC 9", _
                 "Table of Figures", "Table of Authorities"
                Let aStyle.AutomaticallyUpdate = True
            Case Else
                Let aStyle.AutomaticallyUpdate = False
        End Select
        Let aStyle.NoProofing = False   ' also turn on spelling and grammar checking
    Next aStyle
    Let ActiveDocument.UpdateStylesOnOpen = False    ' For information on using this line, see:
    '       http://www.shaunakelly.com/word/shar...matchange.html
    ActiveDocument.Close SaveChanges:=True
    Let Application.ScreenUpdating = True
    Application.ScreenRefresh
    MsgBox title:="All done!", prompt:="All non-TOC styles in the Normal template set to not automatically update."
    On Error GoTo -1
End Sub

Metta · #19 07-16-2025, 06:17 PM

Hi Charles Kenyon
Thank you for sending the language macro I might need in future.
I followed your last instructions several times until eventually the drop down box for styles came up like the one Stefan sent photos of. Even though I followed your instructions the same every time, the drop down box for styles doesn't always look the same. Your advice does seem too be doing the trick now. I also turned off the windows updates, which my friend said throws out all my settings. I hope these steps have stopped the formatting problem forever.
Metta

macropod · #20 07-16-2025, 11:11 PM

Quote:

Originally Posted by Metta

I also turned off the windows updates, which my friend said throws out all my settings.

Neither Windows updates nor Office updates has any effect on your Office settings. Your friend doesn't know what they're taking about.

Stefan Blom · #21 07-17-2025, 02:40 AM

Note that the Modify Style dialog box will look a bit different depending on the type of style you are trying to modify. For example, only paragraph styles will have the "Update automatically" option.

Similar Threads
Thread	Thread Starter	Forum	Replies	Last Post
Macro to search for a particular word, copy the entire paragraph to a new document	Productivity	Word VBA	2	10-25-2019 06:40 AM
Word 2003: Font change is applied to entire document (should not)	ugcheleuce	Word	1	11-05-2018 05:25 AM
Formatting applied to entire document	PoseidonofSea	Word	2	03-08-2018 11:59 AM
How to select and copy to clipboard an entire document except for a paragraph and keep formatting	TD_123	Word VBA	7	06-16-2015 03:30 PM
align just ONE paragraph, not the entire document	vcolemonts	Word	1	02-18-2014 09:57 AM