How can I disable the checkbox defaulting to wildcard search in Find & Replace?

[nsackman]

I used the wildcard F&R once, and now it pops up already checked when I do Ctrl H. Or, more correctly, it pops up most of the time and sometimes it doesn't.

I do heavy typing (.docx) and really pay attention to my productivity, so having to uncheck the wildcard box literally 50-60 times a day is quite annoying!

I should add that I would leave it checked as default, but I also constantly use special characters such as ^p for paragraph, and that doesn't work with wildcard checked.

Anyway, I just can't seem to get rid of it so would be extremely grateful if someone has a solution.

Thanks!

[Charles Kenyon]

1. Open Word, without any documents.
2. Go to the Replace box and click on More so you can see the checkbox.
3. Uncheck it.
4. Close Word.

If that does not work, I suspect you have a macro running that runs a Find using wildcards.

When options are checked in this, they remain active at least for the current Word session. That is why, in macros that use any options or set anything in the find and replace dialog, it is important to return everything to the default at the end of the macro.


Here is a macro that will reset the Find/Replace Dialog settings, should you need it.

Sub FindReplaceDefaultsReset()
'
' Reset Find/Replace dialog to defaults
' Charles Kenyon 2023-06-11
'
    On Error GoTo NoDoc
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    On Error GoTo -1
    Exit Sub
NoDoc:
    MsgBox "This macro requires an open document."
    On Error GoTo -1
End Sub

Instructions for Installing Macros from Forums or Websites by Graham Mayor, MVP

[nsackman]

Yes - that's it. Thank you! I have a macro that switches LASTNAME, FIRSTNAME to FIRSTNAME LASTNAME and uses a wildcard F&R. I applied your macro to the end of that and it works like a charm.

Thanks again,
Nancy