I got error for Macro script when I used for split large file and convert as HTML

[kishan patel]

Dear all,

I have a large file around 1300 pages and wanted to split by pages and also change file formate as HTML but getting error.

My Macro script is,

Sub BreakOnPage()
' Used to set criteria for moving through the document by page.
Application.Browser.Target = wdBrowsePage

For i = 1 To ActiveDocument.BuiltInDocumentProperties("Number of Pages")

'Select and copy the text to the clipboard


ActiveDocument.Bookmarks("\page").Range.Copy

' Open new document to paste the content of the clipboard into.
Documents.Add
Selection.Paste
' Removes the break that is copied at the end of the page, if any.
Selection.TypeBackspace
ChangeFileOpenDirectory "C:"
DocNum = DocNum + 1
ActiveDocument.SaveAs FileName:="page_" & DocNum & ".html
ActiveDocument.Close

' Move the selection to the next page in the document
Application.Browser.Next
Next i
ActiveDocument.Close savechanges:=wdDoNotSaveChanges
End Sub


Aprreciated for your help.

[gmayor]

There are a couple of issues with your code, but the likely problem issues are that you have not defined the file type and you have not set the save path. Saving to the root of the C:\ drive would almost certainly be blocked by security issues.
It is better to declare your variables and name the documents e.g.

Sub BreakOnPage()
Dim i As Integer
Dim oSource As Document, oTarget As Document
Dim oRng As Range
Dim strPath As String
    strPath = "C:\Path\" 'enter the path here
    ' Used to set criteria for moving through the document by page.
    Application.Browser.Target = wdBrowsePage
    Set oSource = ActiveDocument
    For i = 1 To oSource.BuiltInDocumentProperties("Number of Pages")
        'Set a range to the page
        Set oRng = oSource.Bookmarks("\page").Range
        ' Remove the break that is copied at the end of the page, if any.
        oRng.End = oRng.End - 1
        'Create new document to copy the range to.
        Set oTarget = Documents.Add
        oTarget.Range.FormattedText = oRng.FormattedText
        oTarget.SaveAs FileName:=strPath & "page_" & i & ".html", FileFormat:=wdFormatFilteredHTML
        oTarget.Close
        ' Move the selection to the next page in the document
        Application.Browser.Next
    Next i
    oSource.Close savechanges:=wdDoNotSaveChanges
    Set oSource = Nothing
    Set oTarget = Nothing
    Set oRng = Nothing
End Sub

[kishan patel]

Dear Gmayor,

Thanks for your suggestion, I did same as you told, but it showing same error.

see attached image,

[gmayor]

Does the path (strPath) exist?