Macro for printing

[LooKLooK]

Hi there everyone, i would like to ask your help on this matter.



I want to print one document in triplicate, like an invoice that in some part of document it automatically change the word 'original' to 'duplicate' in second print and in third print it changes to triplicate.

Can anyone help me with this? Thanks in advance.

[gmayor]

Bookmark the location where you want the changed text with the bookmark name "CopyNum" Then run the following macro

Sub PrintTriplicate()
'Graham Mayor - https://www.gmayor.com - Last updated - 10 Sep 2020
Dim oRng As Range
Dim Counter As Long
    If ActiveDocument.Bookmarks.Exists("CopyNum") = False Then
        MsgBox "The bookmark 'CopyNum' is missing from the current document.", vbCritical
        GoTo lbl_Exit
    End If
    Set oRng = ActiveDocument.Bookmarks("CopyNum").Range
    For Counter = 1 To 3
        Select Case Counter
            Case 1
                oRng.Text = "Original"
            Case 2
                oRng.Text = "Duplicate"
            Case 3
                oRng.Text = "Triplicate"
        End Select
        ActiveDocument.PrintOut
        oRng.Bookmarks.Add "CopyNum"
    Next
lbl_Exit:
    Set oRng = Nothing
    Exit Sub
End Sub

[LooKLooK]

Lovely reply. Thank you its done. You might close the thread